fl.controls.LabelButton (ActionScript 3.0)

公共属性

	属性		定义方
		accessibilityProperties : AccessibilityProperties 此显示对象的当前辅助功能选项。	DisplayObject
		alpha : Number 指示指定对象的 Alpha 透明度值。	DisplayObject
		autoRepeat : Boolean 获取或设置一个布尔值，该值指示是否当用户在组件上按住鼠标按键时重复调度 buttonDown 事件。	BaseButton
		blendMode : String BlendMode 类中的一个值，用于指定要使用的混合模式。	DisplayObject
		buttonMode : Boolean 指定此 sprite 的按钮模式。	Sprite
		cacheAsBitmap : Boolean 如果设置为 true，则 Flash Player 将缓存显示对象的内部位图表示形式。	DisplayObject
		constructor : Object 对类对象或给定对象实例的构造函数的引用。	Object
		contextMenu : ContextMenu 指定与此对象相关联的上下文菜单。	InteractiveObject
		doubleClickEnabled : Boolean 指定此对象是否接收 doubleClick 事件。	InteractiveObject
		dropTarget : DisplayObject [read-only] 指定拖动 sprite 时经过的显示对象，或放置 sprite 的显示对象。	Sprite
		enabled : Boolean 获取或设置一个值，指示组件能否接受用户输入。	BaseButton
		filters : Array 包含当前与显示对象关联的每个滤镜对象的索引数组。	DisplayObject
		focusEnabled : Boolean 获取或设置一个布尔值，该值指示组件是否可以在用户单击它后获得焦点。	UIComponent
		focusManager : IFocusManager 获取或设置为此组件及其同级组件控制焦点的 FocusManager。	UIComponent
		focusRect : Object 指定此对象是否显示焦点矩形。	InteractiveObject
		graphics : Graphics [read-only] 指定属于此 sprite 的 Graphics 对象，在此 sprite 中可执行矢量绘画命令。	Sprite
		height : Number 获取或设置组件的高度，以像素为单位。	UIComponent
		hitArea : Sprite 指定一个 sprite 用作另一个 sprite 的点击区域。	Sprite
		label : String 获取或设置组件的文本标签。	LabelButton
		labelPlacement : String 标签相对于指定图标的位置。	LabelButton
		loaderInfo : LoaderInfo [read-only] 返回一个 LoaderInfo 对象，其中包含加载此显示对象所属的文件的相关信息。	DisplayObject
		mask : DisplayObject 调用显示对象被指定的 mask 对象遮罩。	DisplayObject
		mouseChildren : Boolean 确定对象的子项是否支持鼠标。	DisplayObjectContainer
		mouseEnabled : Boolean 指定此对象是否接收鼠标消息。	InteractiveObject
		mouseFocusEnabled : Boolean 获取或设置一个值，该值指示组件是否可以在用户单击它后获得焦点。	UIComponent
		mouseX : Number [read-only] 指示鼠标位置的 x 坐标，以像素为单位。	DisplayObject
		mouseY : Number [read-only] 指示鼠标位置的 y 坐标，以像素为单位。	DisplayObject
		name : String 指示 DisplayObject 的实例名称。	DisplayObject
		numChildren : int [read-only] 返回此对象的子项数目。	DisplayObjectContainer
		opaqueBackground : Object 指定显示对象是否由于具有某种背景颜色而不透明。	DisplayObject
		parent : DisplayObjectContainer [read-only] 指示包含此显示对象的 DisplayObjectContainer 对象。	DisplayObject
		prototype : Object [static] 对类或函数对象的原型对象的引用。	Object
		root : DisplayObject [read-only] 对于加载的 SWF 文件中的显示对象，root 属性是此 SWF 文件所表示的显示列表树结构部分中的顶级显示对象。	DisplayObject
		rotation : Number 指示 DisplayObject 实例距其原始方向的旋转程度，以度为单位。	DisplayObject
		scale9Grid : Rectangle 当前有效的缩放网格。	DisplayObject
		scaleX : Number 将组件的当前宽度与缩放系数相乘。	UIComponent
		scaleY : Number 将组件的当前高度与缩放系数相乘。	UIComponent
		scrollRect : Rectangle 显示对象的滚动矩形范围。	DisplayObject
		selected : Boolean 获取或设置一个布尔值，指示切换按钮是否已切换至打开或关闭位置。	LabelButton
		soundTransform : SoundTransform 控制此 sprite 中的声音。	Sprite
		stage : Stage [read-only] 显示对象的舞台。	DisplayObject
		tabChildren : Boolean 确定对象的子项是否支持 Tab 键。	DisplayObjectContainer
		tabEnabled : Boolean 指定此对象是否遵循 Tab 键顺序。	InteractiveObject
		tabIndex : int 指定 SWF 文件中的对象按 Tab 键顺序排列。	InteractiveObject
		textField : TextField 对组件内部文本字段的引用。	LabelButton
		textSnapshot : TextSnapshot [read-only] 返回此 DisplayObjectContainer 实例的 TextSnapshot 对象。	DisplayObjectContainer
		toggle : Boolean 获取或设置一个布尔值，指示按钮能否进行切换。	LabelButton
		transform : Transform 一个对象，具有与显示对象的矩阵、颜色转换和像素范围有关的属性。	DisplayObject
		useHandCursor : Boolean 布尔值，指示当鼠标滑过其 buttonMode 属性设置为 true 的 sprite 时是否显示手指形（手形光标）。	Sprite
		version : String = "3.0.0.13" 组件的版本号。	UIComponent
		visible : Boolean 获取或设置一个值，该值指示当前组件实例是否可见。	UIComponent
		width : Number 获取或设置组件的宽度（以像素为单位）。	UIComponent
		x : Number 获取或设置 x 坐标，该坐标表示组件在其父容器内沿 x 轴的位置。	UIComponent
		y : Number 获取或设置 y 坐标，该坐标表示组件在其父容器内沿 y 轴的位置。	UIComponent

公共方法

隐藏继承的公共方法

显示继承的公共方法

	方法		定义方
		LabelButton() 创建新的 LabelButton 组件实例。	LabelButton
		addChild(child:DisplayObject):DisplayObject 将一个 DisplayObject 子实例添加到该 DisplayObjectContainer 实例中。	DisplayObjectContainer
		addChildAt(child:DisplayObject, index:int):DisplayObject 将一个 DisplayObject 子实例添加到该 DisplayObjectContainer 实例中。	DisplayObjectContainer
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void 使用 EventDispatcher 对象注册事件侦听器对象，以使侦听器能够接收事件通知。	EventDispatcher
		areInaccessibleObjectsUnderPoint(point:Point):Boolean 指示安全限制是否会导致出现以下情况：在列表中忽略了使用指定 point 点调用 DisplayObjectContainer.getObjectsUnderPoint() 方法时返回的所有显示对象。	DisplayObjectContainer
		clearStyle(style:String):void 删除此组件实例中的样式属性。	UIComponent
		contains(child:DisplayObject):Boolean 确定指定显示对象是 DisplayObjectContainer 实例的子项还是该实例本身。	DisplayObjectContainer
		dispatchEvent(event:Event):Boolean 将事件调度到事件流中。	EventDispatcher
		drawFocus(focused:Boolean):void 在此组件上显示或隐藏焦点指示符。	UIComponent
		drawNow():void 启动立即绘制操作，但不像 invalidateNow 那样使全部设置失效。	UIComponent
		getBounds(targetCoordinateSpace:DisplayObject):Rectangle 返回一个矩形，该矩形定义相对于 targetCoordinateSpace 对象坐标系的显示对象区域。	DisplayObject
		getChildAt(index:int):DisplayObject 返回位于指定索引处的子显示对象实例。	DisplayObjectContainer
		getChildByName(name:String):DisplayObject 返回具有指定名称的子显示对象。	DisplayObjectContainer
		getChildIndex(child:DisplayObject):int 返回 DisplayObject 的 child 实例的索引位置。	DisplayObjectContainer
		getFocus():InteractiveObject 检索当前具有焦点的对象。	UIComponent
		getObjectsUnderPoint(point:Point):Array 返回对象的数组，这些对象位于指定点下，并且是该 DisplayObjectContainer 实例的子项（或孙子项，依此类推）。	DisplayObjectContainer
		getRect(targetCoordinateSpace:DisplayObject):Rectangle 返回一个矩形，该矩形根据 targetCoordinateSpace 参数定义的坐标系定义显示对象的边界，但不包括形状上的任何笔触。	DisplayObject
		getStyle(style:String):Object 检索组件的样式查找链中设置的样式属性。	UIComponent
		getStyleDefinition():Object [static] 检索当前组件的默认样式映射。	LabelButton
		globalToLocal(point:Point):Point 将 point 对象从舞台（全局）坐标转换为显示对象的（本地）坐标。	DisplayObject
		hasEventListener(type:String):Boolean 检查 EventDispatcher 对象是否为特定事件类型注册了任何侦听器。	EventDispatcher
		hasOwnProperty(name:String):Boolean 指示对象是否已经定义了指定的属性。	Object
		hitTestObject(obj:DisplayObject):Boolean 计算显示对象，以确定它是否与 obj 显示对象重叠或相交。	DisplayObject
		hitTestPoint(x:Number, y:Number, shapeFlag:Boolean = false):Boolean 计算显示对象，以确定它是否与 x 和 y 参数指定的点重叠或相交。	DisplayObject
		invalidate(property:String, callLater:Boolean = true):void 在未另外指定的情况下，将属性标记为无效，并在下一帧上重绘组件。	UIComponent
		isPrototypeOf(theClass:Object):Boolean 指示 Object 类的实例是否在指定为参数的对象的原型链中。	Object
		localToGlobal(point:Point):Point 将 point 对象从显示对象的（本地）坐标转换为舞台（全局）坐标。	DisplayObject
		mergeStyles(... list):Object [static] 将多个类的样式合并到一个对象中。	UIComponent
		move(x:Number, y:Number):void 将组件移动到其父项内的指定位置。	UIComponent
		propertyIsEnumerable(name:String):Boolean 指示指定的属性是否存在、是否可枚举。	Object
		removeChild(child:DisplayObject):DisplayObject 从 DisplayObjectContainer 实例的子列表中删除指定的 child DisplayObject 实例。	DisplayObjectContainer
		removeChildAt(index:int):DisplayObject 从 DisplayObjectContainer 的子列表中指定的 index 位置删除子 DisplayObject。	DisplayObjectContainer
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void 从 EventDispatcher 对象中删除侦听器。	EventDispatcher
		setChildIndex(child:DisplayObject, index:int):void 更改现有子项在显示对象容器中的位置。	DisplayObjectContainer
		setFocus():void 设置此组件的焦点。	UIComponent
		setMouseState(state:String):void 通过 ActionScript 设置鼠标状态。	BaseButton
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 设置循环操作动态属性的可用性。	Object
		setSize(width:Number, height:Number):void 将组件设置为指定宽度和高度。	UIComponent
		setStyle(style:String, value:Object):void 对此组件实例设置样式属性。	UIComponent
		startDrag(lockCenter:Boolean = false, bounds:Rectangle = null):void 允许用户拖动指定的 Sprite。	Sprite
		stopDrag():void 结束 startDrag() 方法。	Sprite
		swapChildren(child1:DisplayObject, child2:DisplayObject):void 交换两个指定子对象的 Z 轴顺序（从前到后顺序）。	DisplayObjectContainer
		swapChildrenAt(index1:int, index2:int):void 在子级列表中两个指定的索引位置，交换子对象的 Z 轴顺序（前后顺序）。	DisplayObjectContainer
		toString():String 返回指定对象的字符串表示形式。	Object
		validateNow():void 验证并更新此对象的属性和布局，如果需要的话重绘对象。	UIComponent
		valueOf():Object 返回指定对象的原始值。	Object
		willTrigger(type:String):Boolean 检查是否用此 EventDispatcher 对象或其任何始祖为指定事件类型注册了事件侦听器。	EventDispatcher

摘要	定义方
activate	Flash Player 获得操作系统焦点并变为活动状态时调度。	EventDispatcher
added	将显示对象添加到显示列表中时调度。	DisplayObject
addedToStage	在将显示对象直接添加到舞台显示列表或将包含显示对象的子树添加至舞台显示列表中时调度。	DisplayObject
buttonDown	当用户按下 Button 组件时调度。	BaseButton
change	当切换 Button 组件的 selected 属性值发生更改时调度。	BaseButton
click	当切换按钮接收到来自鼠标设备或空格键的输入后调度。	LabelButton
deactivate	Flash Player 失去操作系统焦点并变为非活动状态时调度。	EventDispatcher
doubleClick	如果 InteractiveObject 的 doubleClickEnabled 标志设置为 true，当用户在该对象上快速连续按下两次并释放指针设备的主按钮时调度。	InteractiveObject
enterFrame	播放头进入新帧时调度。	DisplayObject
focusIn	显示对象获得焦点后调度。	InteractiveObject
focusOut	显示对象失去焦点后调度。	InteractiveObject
hide	在组件可见性从可见改为不可见以后调度。	UIComponent
keyDown	用户按下某个键时调度。	InteractiveObject
keyFocusChange	用户尝试使用键盘导航更改焦点时调度。	InteractiveObject
keyUp	用户释放某个键时调度。	InteractiveObject
labelChange	当标签值发生变化后调度。	LabelButton
mouseDown	在 Flash Player 窗口中，用户在 InteractiveObject 实例上按下指针设备按钮时调度。	InteractiveObject
mouseFocusChange	用户尝试使用指针设备更改焦点时调度。	InteractiveObject
mouseMove	用户移动 InteractiveObject 上的指针设备时调度。	InteractiveObject
mouseOut	用户将指针设备从 InteractiveObject 实例上移开时调度。	InteractiveObject
mouseOver	在 Flash Player 窗口中，用户将指针设备移动到 InteractiveObject 实例上时调度。	InteractiveObject
mouseUp	在 Flash Player 窗口中，用户在 InteractiveObject 实例上释放指针设备按钮时调度。	InteractiveObject
mouseWheel	在 Flash Player 窗口中，鼠标滚轮滚动到 InteractiveObject 实例上时调度。	InteractiveObject
move	在移动组件以后调度。	UIComponent
removed	将要从显示列表中删除显示对象时调度。	DisplayObject
removedFromStage	在从显示列表中直接删除显示对象或删除包含显示对象的子树时调度。	DisplayObject
render	将要更新和呈现显示列表时调度。	DisplayObject
resize	在调整组件大小以后调度。	UIComponent
rollOut	用户将指针设备从 InteractiveObject 实例上移开时调度。	InteractiveObject
rollOver	用户将指针设备移动到 InteractiveObject 实例上时调度。	InteractiveObject
show	在组件可见性从不可见改为可见以后调度。	UIComponent
tabChildrenChange	对象的 tabChildren 标志值发生更改时调度。	InteractiveObject
tabEnabledChange	对象的 tabEnabled 标志发生更改时调度。	InteractiveObject
tabIndexChange	对象的 tabIndex 属性值发生更改时调度。	InteractiveObject

样式

隐藏继承的样式

显示继承的样式

	说明	定义方
disabledIcon	类型: Class 类的名称，该类用作未禁用按钮时的图标。默认值为 `null`.	LabelButton
disabledSkin	类型: Class 类的名称，该类用作当未选择按钮且按钮已被禁用时背景和边框的外观。默认值为 `Button_disabledSkin`.	LabelButton
disabledTextFormat	类型: flash.text.TextFormat 用于在禁用了按钮的情况下呈现组件标签的 TextFormat 对象。默认值为 `TextFormat("_sans", 11, 0x999999, false, false, false, '', '', TextFormatAlign.LEFT, 0, 0, 0, 0)`.	UIComponent
downIcon	类型: Class 类的名称，该类用作当未选择按钮而按下了鼠标按键时的图标。默认值为 `null`.	LabelButton
downSkin	类型: Class 类的名称，该类用作当未选择按钮而按下了鼠标按键时背景和边框的外观。默认值为 `Button_downSkin`.	LabelButton
embedFonts	类型: Boolean 指示是否使用嵌入字体轮廓呈现文本字段。如果该值为 true，则 Flash Player 使用嵌入字体轮廓呈现文本字段。如果该值为 false，则 Flash Player 使用设备字体呈现文本字段。如果将文本字段的 embedFonts 属性设置为 true，则必须使用应用于该文本字段的 TextFormat 对象的 font 属性来指定该文本的字体。如果指定的字体没有嵌入 SWF 文件中，则不会显示该文本。默认值为 `false`.	LabelButton
focusRectPadding	类型: Number 格式: Length 用于分隔组件的外边框和焦点指示符的外边框的填充（以像素为单位）。默认值为 `2`.	UIComponent
focusRectSkin	类型: Class 用于显示焦点指示符的外观。默认值为 `focusRectSkin`.	UIComponent
icon	类型: Class 类的名称，该类用作当未选择切换按钮且鼠标光标不在按钮上方时的图标。默认值为 `null`.	LabelButton
overIcon	类型: Class 类的名称，该类用作当未选择按钮且鼠标光标在组件上方时的图标。默认值为 `null`.	LabelButton
overSkin	类型: Class 类的名称，该类用作当未选择按钮且鼠标光标位于组件上方时背景和边框的外观。默认值为 `Button_overSkin`.	LabelButton
repeatDelay	类型: Number 格式: Time 在第一次调度 `buttonDown` 事件之后、发送第二个 `buttonDown` 事件之前等待的毫秒数。. 默认值为 `500`.	LabelButton
repeatInterval	类型: Number 格式: Time 在由 `repeatDelay` 样式指定的延迟之后调度的 `buttonDown` 事件之间的间隔（以毫秒为单位）。. 默认值为 `35`.	LabelButton
selectedDisabledIcon	类型: Class 类的名称，该类用作当选择了按钮而按钮已被禁用时的图标。默认值为 `null`.	LabelButton
selectedDisabledSkin	类型: Class 类的名称，该类用作当选择了切换按钮而切换按钮已被禁用时背景和边框的外观。默认值为 `Button_selectedDisabledSkin`.	LabelButton
selectedDownIcon	类型: Class 类的名称，该类用作当选择了按钮且按下了鼠标按键时的图标。默认值为 `null`.	LabelButton
selectedDownSkin	类型: Class 类的名称，该类用作当选择了切换按钮且按下了鼠标按键时背景和边框的外观。默认值为 `Button_selectedDownSkin`.	LabelButton
selectedOverIcon	类型: Class 类的名称，该类用作当选择了按钮且鼠标光标在组件上方时的图标。默认值为 `null`.	LabelButton
selectedOverSkin	类型: Class 类的名称，该类用作当选择了切换按钮且鼠标光标在组件上方时背景和边框的外观。默认值为 `Button_selectedOverSkin`.	LabelButton
selectedUpIcon	类型: Class 类的名称，该类用作当选择了按钮且松开了鼠标按键时的图标。默认值为 `null`.	LabelButton
selectedUpSkin	类型: Class 类的名称，该类用作当选择了切换按钮且鼠标光标不在组件上方时背景和边框的外观。默认值为 `Button_selectedUpSkin`.	LabelButton
textFormat	类型: flash.text.TextFormat 用于呈现组件标签的 TextFormat 对象。默认值为 `TextFormat("_sans", 11, 0x000000, false, false, false, '', '', TextFormatAlign.LEFT, 0, 0, 0, 0)`.	UIComponent
textPadding	类型: Number 格式: Length 文本和组件边缘之间的距离，以及文本和图标之间的距离（以像素为单位）。默认值为 `5`.	LabelButton
upIcon	类型: Class 类的名称，该类用作当未选择切换按钮且鼠标光标不在按钮上方时的图标。默认值为 `null`.	LabelButton
upSkin	类型: Class 类的名称，该类用作当未选择按钮且鼠标光标不在组件上方时背景和边框的外观。默认值为 `Button_upSkin`.	LabelButton

属性详细信息

label

属性

label:String [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

获取或设置组件的文本标签。默认情况下，标签文本显示在按钮的中央。

注意：设置此属性将促使 labelChange 事件对象被调度。

默认值为 "Label".

实现
public function get label():String
public function set label(value:String):void

另请参见

labelChange

labelPlacement

属性

labelPlacement:String [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

标签相对于指定图标的位置。

在 ActionScript 中，可以使用以下常量来设置此属性：

ButtonLabelPlacement.RIGHT
ButtonLabelPlacement.LEFT
ButtonLabelPlacement.BOTTOM
ButtonLabelPlacement.TOP

默认值为 ButtonLabelPlacement.RIGHT.

实现
public function get labelPlacement():String
public function set labelPlacement(value:String):void

另请参见

ButtonLabelPlacement

示例
如何使用示例

下例创建一个 Button 组件实例，并将其 labelPlacement 属性设置为 ButtonLabelPlacement.BOTTOM：


import fl.controls.Button;
import fl.controls.ButtonLabelPlacement;

var myButton:Button = new Button();
myButton.label = "ButtonLabelPlacement.BOTTOM";
myButton.labelPlacement = ButtonLabelPlacement.BOTTOM;
myButton.setStyle("icon", myLibraryAsset);
myButton.setSize(200, 100);
myButton.move(10, 10);
addChild(myButton);

selected

属性

selected:Boolean [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

获取或设置一个布尔值，指示切换按钮是否已切换至打开或关闭位置。 true 值指示按钮已切换至打开位置；false 值指示按钮已切换至关闭位置。仅在以下情况才能设置此属性：toggle 属性设置为 true 时。

对于 CheckBox 组件，该值指示此框是否显示选中标记。对于 RadioButton 组件，该值指示此组件是否处于选中状态。

用户可以通过单击组件来更改此属性，但是也可以通过编程方式来设置此属性。

如果 toggle 属性设置为 true，则更改此属性还会调度 change 事件。

默认值为 false.

实现
public function get selected():Boolean
public function set selected(value:Boolean):void

示例
如何使用示例

下例演示如何通过使用 toggle 属性并侦听 change 事件以确定按钮何时处于选中状态来创建切换按钮：


import fl.controls.Button;

var myButton:Button = new Button();
myButton.toggle = true;
myButton.move(10, 10);
myButton.addEventListener(Event.CHANGE, changeHandler);
addChild(myButton);

function changeHandler(event:Event):void {
    trace("Button toggled (selected:" + event.currentTarget.selected + ")");
}

textField

属性

public var textField:TextField

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

对组件内部文本字段的引用。

toggle

属性

toggle:Boolean [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

获取或设置一个布尔值，指示按钮能否进行切换。 true 值指示按钮可以进行切换；false 指示按钮不能进行切换。

如果该值为 true，则单击按钮将在选中状态和未选中状态之间进行切换。可以通过编程方式获取或设置此状态，方法是使用 selected 属性。

如果该值为 false，则用户释放按钮后，它不再保持按下状态。在这种情况下，它的 selected 属性始终为 false。

注意：当 toggle 设置为 false 时，selected 将强制成为 false，因为只能选择切换按钮。

默认值为 false.

实现
public function get toggle():Boolean
public function set toggle(value:Boolean):void

示例
如何使用示例

下例创建一个可切换的 Button，方法是将其 toggle 属性设置为 true，并侦听要调度的 change 事件：


import fl.controls.Button;

var myButton:Button = new Button();
myButton.toggle = true;
myButton.selected = true;
myButton.label = "selected:" + myButton.selected;
myButton.width = 120;
myButton.move(10, 10);
myButton.addEventListener(Event.CHANGE, changeHandler);
addChild(myButton);

function changeHandler(event:Event):void {
    var myBtn:Button = event.currentTarget as Button;
    myBtn.label = "selected:" + myBtn.selected;
}

构造函数详细信息

LabelButton

()

构造函数

public function LabelButton()

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

创建新的 LabelButton 组件实例。

方法详细信息

getStyleDefinition

()

方法

public static function getStyleDefinition():Object

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

检索当前组件的默认样式映射。样式映射包含适合组件的类型，具体取决于组件使用的样式。例如，disabledTextFormat 样式包含 null 值或 TextFormat 对象。可以使用这些样式并对当前组件调用 setStyle()。下面的代码覆盖指定组件上默认的 disabledTextFormat 样式：

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Object — 默认样式对象。

另请参见

fl.core.UIComponent.getStyle()
fl.core.UIComponent.setStyle()
fl.managers.StyleManager

示例
如何使用示例

下例为多个组件类创建一个样式浏览器：

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

事件详细信息

click

事件

事件对象类型: flash.events.MouseEvent
MouseEvent.type property = flash.events.MouseEvent.CLICK

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

当切换按钮接收到来自鼠标设备或空格键的输入后调度。

定义 click 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`true`
`buttonDown`	如果按下鼠标主按键，则为 `true`；否则为 `false`。
`cancelable`	`false`；没有要取消的默认行为。
`ctrlKey`	如果 Ctrl 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`localX`	事件发生点的相对于包含 Sprite 的水平坐标。
`localY`	事件发生点的相对于包含 Sprite 的垂直坐标。
`shiftKey`	如果 Shift 键处于活动状态，则为 `true`；如果处于非活动状态，则为 `false`。
`stageX`	事件发生点在全局舞台坐标中的水平坐标。
`stageY`	事件发生点在全局舞台坐标中的垂直坐标。
`target`	指针设备下的 InteractiveObject 实例。 `target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。

示例
如何使用示例

下例创建一个 Button 组件实例，并侦听要调度的 click 事件：


import fl.controls.Button;

var myButton:Button = new Button();
myButton.label = "Click me";
myButton.addEventListener(MouseEvent.CLICK, clickHandler);
myButton.move(10, 10);
addChild(myButton);

function clickHandler(event:MouseEvent):void {
    trace("clicked (localX:" + event.localX + ", localY:" + event.localY + ")");
}

labelChange

事件

事件对象类型: fl.events.ComponentEvent
ComponentEvent.type property = fl.events.ComponentEvent.LABEL_CHANGE

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

当标签值发生变化后调度。

定义 labelChange 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理事件对象的对象。
`target`	调度了事件的对象。target 不一定是侦听该事件的对象。使用 `currentTarget` 属性可以访问侦听该事件的对象。

示例
如何使用示例

下例创建一个 Button 组件实例，并侦听 labelChange 事件，每当该按钮的 label 属性更改时就会调度该事件。


import fl.controls.Button;
import fl.events.ComponentEvent;

var myButton:Button = new Button();
myButton.addEventListener(ComponentEvent.LABEL_CHANGE, labelChangeHandler);
myButton.label = "Click me";
myButton.move(10, 10);
addChild(myButton);

function labelChangeHandler(event:ComponentEvent):void {
    trace("labelChange: " + event.currentTarget.label);
}

示例如何使用示例

此示例扩展了 LabelButton 类的功能，将创建一个在指针滑过时显示工具提示的图标。

若要运行该示例，请按照下列步骤操作：

将 List 和 Button 组件添加到库中。
创建一个图标元件，并将其命名为 MyIcon。
在 MyIcon 的元件属性中，选中“为 ActionScript 导出”选项。
将该代码作为 LabelButtonExample.as 另存到 FLA 文件所在的同一目录中。
将 FLA 文件中的 Document 类设置为 LabelButtonExample。

package
{ 
    import flash.display.Sprite;
    import flash.events.Event;
    import fl.data.DataProvider;
    import fl.controls.List;
    import fl.controls.ComboBox;
    import fl.core.UIComponent;
    import fl.events.ListEvent;
    
    public class LabelButtonExample extends Sprite
    {
        public function LabelButtonExample() {
            var myIcon:IconWithToolTip = new IconWithToolTip();
            myIcon.setStyle("icon", MyIcon);
            myIcon.iconDescription = "Icon Description";
            myIcon.move(50,50);
            addChild(myIcon);
        }
    }
}

将下面的代码作为 IconWithToolTip.as 另存到 FLA 文件所在的同一目录中：

package {
    import fl.controls.LabelButton;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;
    
    public class IconWithToolTip extends LabelButton
    {
        public var iconDescription:String = "";
        private var toolTip:TextField;
        private var format:TextFormat;
        
        public function IconWithToolTip() {
            addEventListener(MouseEvent.MOUSE_OVER,showToolTip);
            addEventListener(MouseEvent.MOUSE_OUT,hideToolTip);
            format = new TextFormat();
            format.font = "Verdana";
            format.size = 10;
            format.bold = true;
            createToolTip();
        }

        private function createToolTip():void {
            toolTip = new TextField();
            toolTip.background = true;
            toolTip.backgroundColor = 0xFFCC66;
            toolTip.border = true;
            toolTip.borderColor = 0x000000;
            toolTip.multiline = false;
            toolTip.autoSize = TextFieldAutoSize.CENTER;
            toolTip.visible = false;
            addChild(toolTip);            
        }

        private function showToolTip(e:MouseEvent):void {
            toolTip.text = iconDescription;
            toolTip.x = 20;
            toolTip.y = 0;
            toolTip.visible = true;
            toolTip.setTextFormat(format);
        }

        private function hideToolTip(e:MouseEvent):void {
            toolTip.visible = false;    
        }
    }
}

当前页: http://livedocs.adobe.com/flash/9.0_cn/ActionScriptLangRefV3/fl/controls/LabelButton.html

ActionScript 3.0 语言和组件参考		全部包 \| 全部类 \| 语言元素 \| 索引 \| 附录 \| 约定 \| 帧无帧
LabelButton	属性 \| 方法 \| 事件 \| 样式 \| 示例

包	fl.controls
类	public class LabelButton
继承	LabelButton BaseButton UIComponent Sprite DisplayObjectContainer InteractiveObject DisplayObject EventDispatcher Object
实现	IFocusManagerComponent
子类	Button, CellRenderer, CheckBox, HeaderRenderer, RadioButton