fl.events.ComponentEvent (ActionScript 3.0)

	属性	定义方
		bubbles : Boolean [read-only] 指示事件是否为冒泡事件。	Event
		cancelable : Boolean [read-only] 指示是否可以阻止与事件相关联的行为。	Event
		constructor : Object 对类对象或给定对象实例的构造函数的引用。	Object
		currentTarget : Object [read-only] 当前正在使用某个事件侦听器处理 Event 对象的对象。	Event
		eventPhase : uint [read-only] 事件流中的当前阶段。	Event
		prototype : Object [static] 对类或函数对象的原型对象的引用。	Object
		target : Object [read-only] 事件目标。	Event
		type : String [read-only] 事件的类型。	Event

	方法	定义方
		ComponentEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false) 创建包含有关组件事件信息的新 ComponentEvent 对象。	ComponentEvent
		clone():Event 创建 ComponentEvent 对象的副本，并设置每个参数的值以匹配原始参数值。	ComponentEvent
		formatToString(className:String, ... arguments):String 在自定义 Event 类中实现 toString() 方法的实用程序函数。	Event
		hasOwnProperty(name:String):Boolean 指示对象是否已经定义了指定的属性。	Object
		isDefaultPrevented():Boolean 检查是否已对事件调用 preventDefault()。	Event
		isPrototypeOf(theClass:Object):Boolean 指示 Object 类的实例是否在指定为参数的对象的原型链中。	Object
		preventDefault():void 如果可以取消事件的默认行为，则取消该行为。	Event
		propertyIsEnumerable(name:String):Boolean 指示指定的属性是否存在、是否可枚举。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 设置循环操作动态属性的可用性。	Object
		stopImmediatePropagation():void 防止对事件流中当前节点中和所有后续节点中的事件侦听器进行处理。	Event
		stopPropagation():void 防止对事件流中当前节点的后续节点中的所有事件侦听器进行处理。	Event
		toString():String 返回一个字符串，其中包含 ComponentEvent 对象的所有属性。	ComponentEvent
		valueOf():Object 返回指定对象的原始值。	Object

	常量	定义方
		ACTIVATE : String = "activate" [static] 定义 activate 事件对象的 type 属性值。	Event
		ADDED : String = "added" [static] 定义 added 事件对象的 type 属性值。	Event
		ADDED_TO_STAGE : String = "addedToStage" [static] 定义 addedToStage 事件对象的 type 属性值。	Event
		BUTTON_DOWN : String = "buttonDown" [static] 定义 buttonDown 事件对象的 type 属性值。	ComponentEvent
		CANCEL : String = "cancel" [static] 定义 cancel 事件对象的 type 属性值。	Event
		CHANGE : String = "change" [static] 定义 change 事件对象的 type 属性值。	Event
		CLOSE : String = "close" [static] 定义 close 事件对象的 type 属性值。	Event
		COMPLETE : String = "complete" [static] 定义 complete 事件对象的 type 属性值。	Event
		CONNECT : String = "connect" [static] 定义 connect 事件对象的 type 属性值。	Event
		DEACTIVATE : String = "deactivate" [static] 定义 deactivate 事件对象的 type 属性值。	Event
		ENTER : String = "enter" [static] 定义 enter 事件对象的 type 属性值。	ComponentEvent
		ENTER_FRAME : String = "enterFrame" [static] 定义 enterFrame 事件对象的 type 属性值。	Event
		FULLSCREEN : String = "fullScreen" [static] 定义 fullScreen 事件对象的 type 属性值。	Event
		HIDE : String = "hide" [static] 定义 hide 事件对象的 type 属性值。	ComponentEvent
		ID3 : String = "id3" [static] 定义 id3 事件对象的 type 属性值。	Event
		INIT : String = "init" [static] 定义 init 事件对象的 type 属性值。	Event
		LABEL_CHANGE : String = "labelChange" [static] 定义 labelChange 事件对象的 type 属性值。	ComponentEvent
		MOUSE_LEAVE : String = "mouseLeave" [static] 定义 mouseLeave 事件对象的 type 属性值。	Event
		MOVE : String = "move" [static] 定义 move 事件对象的 type 属性值。	ComponentEvent
		OPEN : String = "open" [static] 定义 open 事件对象的 type 属性值。	Event
		REMOVED : String = "removed" [static] 定义 removed 事件对象的 type 属性值。	Event
		REMOVED_FROM_STAGE : String = "removedFromStage" [static] 定义 removedFromStage 事件对象的 type 属性值。	Event
		RENDER : String = "render" [static] 定义 render 事件对象的 type 属性值。	Event
		RESIZE : String = "resize" [static] 定义 resize 事件对象的 type 属性值。	ComponentEvent
		SCROLL : String = "scroll" [static] 定义 scroll 事件对象的 type 属性值。	Event
		SELECT : String = "select" [static] 定义 select 事件对象的 type 属性值。	Event
		SHOW : String = "show" [static] 定义 show 事件对象的 type 属性值。	ComponentEvent
		SOUND_COMPLETE : String = "soundComplete" [static] 定义 soundComplete 事件对象的 type 属性值。	Event
		TAB_CHILDREN_CHANGE : String = "tabChildrenChange" [static] 定义 tabChildrenChange 事件对象的 type 属性值。	Event
		TAB_ENABLED_CHANGE : String = "tabEnabledChange" [static] 定义 tabEnabledChange 事件对象的 type 属性值。	Event
		TAB_INDEX_CHANGE : String = "tabIndexChange" [static] 定义 tabIndexChange 事件对象的 type 属性值。	Event
		UNLOAD : String = "unload" [static] 定义 unload 事件对象的 type 属性值。	Event

构造函数详细信息

ComponentEvent

()

构造函数

public function ComponentEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false)

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

创建包含有关组件事件信息的新 ComponentEvent 对象。ComponentEvent 对象作为参数传递到事件侦听器。

参数

	`type:String` — 事件的类型。事件侦听器可以通过事件对象的 `type` 属性来访问此信息。组件可以具有以下事件类型：`ComponentEvent.BUTTON_DOWN`、`ComponentEvent.ENTER`、`ComponentEvent.HIDE`、`ComponentEvent.LABEL_CHANGE`、`ComponentEvent.MOVE`、`ComponentEvent.RESIZE` 和 `ComponentEvent.SHOW`。

	`bubbles:Boolean` (default = `false`) — 确定 ComponentEvent 对象是否参与事件流的 Bubbling 阶段。事件侦听器可以通过事件对象的 `bubbles` 属性来访问此信息。

	`cancelable:Boolean` (default = `false`) — 确定是否可以取消 ComponentEvent 对象。事件侦听器可以通过事件对象的 `cancelable` 属性来访问此信息。

方法详细信息

clone

()

方法

public override function clone():Event

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

创建 ComponentEvent 对象的副本，并设置每个参数的值以匹配原始参数值。

Event — 其属性值与原始属性值匹配的新 ComponentEvent 对象。

toString

()

方法

public override function toString():String

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

返回一个字符串，其中包含 ComponentEvent 对象的所有属性。字符串的格式如下：[ComponentEvent type=value bubbles=value cancelable=value]

String — ComponentEvent 对象的字符串表示形式。

常量详细信息

BUTTON_DOWN

常量

public static const BUTTON_DOWN:String = "buttonDown"

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

定义 buttonDown 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理事件对象的对象。
`target`	调度了事件的对象。target 不一定是侦听该事件的对象。使用 `currentTarget` 属性可以访问侦听该事件的对象。

ENTER

常量

public static const ENTER:String = "enter"

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

定义 enter 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理事件对象的对象。
`target`	调度了事件的对象。target 不一定是侦听该事件的对象。使用 `currentTarget` 属性可以访问侦听该事件的对象。

HIDE

常量

public static const HIDE:String = "hide"

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

定义 hide 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理事件对象的对象。
`target`	调度了事件的对象。target 不一定是侦听该事件的对象。使用 `currentTarget` 属性可以访问侦听该事件的对象。

另请参见

SHOW

示例
如何使用示例

下例创建一个 Button 组件，用于切换 List 组件的可见性：


import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

LABEL_CHANGE

常量

public static const LABEL_CHANGE:String = "labelChange"

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

定义 labelChange 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理事件对象的对象。
`target`	调度了事件的对象。target 不一定是侦听该事件的对象。使用 `currentTarget` 属性可以访问侦听该事件的对象。

MOVE

常量

public static const MOVE:String = "move"

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

定义 move 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理事件对象的对象。
`target`	调度了事件的对象。target 不一定是侦听该事件的对象。使用 `currentTarget` 属性可以访问侦听该事件的对象。

示例
如何使用示例

下例根据 Slider 组件的值在舞台上重新定位 UILoader 组件实例：


import fl.controls.Slider;
import fl.containers.UILoader;
import fl.events.ComponentEvent;
import fl.events.SliderEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
myUILoader.move(10, 20); 
myUILoader.addEventListener(ComponentEvent.MOVE, moveHandler);
addChild(myUILoader);

var mySlider:Slider = new Slider();
mySlider.liveDragging = true;
mySlider.minimum = myUILoader.x;
mySlider.maximum = myUILoader.x + 200;
mySlider.snapInterval = 1;
mySlider.tickInterval = 10;
mySlider.move(10, 10);
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
addChild(mySlider);

function changeHandler(event:SliderEvent):void {
    myUILoader.x = event.value;
}

function moveHandler(event:ComponentEvent):void {
    trace("[move] x:" + event.currentTarget.x + ", y:" + event.currentTarget.y);
}

RESIZE

常量

public static const RESIZE:String = "resize"

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

定义 resize 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理事件对象的对象。
`target`	调度了事件的对象。target 不一定是侦听该事件的对象。使用 `currentTarget` 属性可以访问侦听该事件的对象。

示例
如何使用示例

下例将外部图像加载到 UILoader 组件实例中，并使用 resize 事件和 move() 方法将该图像居中放置在舞台上：


import fl.containers.UILoader;
import fl.events.ComponentEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.scaleContent = false;
myUILoader.addEventListener(ComponentEvent.RESIZE, resizeHandler);
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
addChild(myUILoader);

function resizeHandler(event:ComponentEvent):void {
    var myImg:UILoader = event.currentTarget as UILoader;
    var newX:uint = (stage.stageWidth - myImg.width) / 2;
    var newY:uint = (stage.stageHeight - myImg.height) / 2;
    myImg.move(newX, newY);
}

SHOW

常量

public static const SHOW:String = "show"

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

定义 show 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`false`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理事件对象的对象。
`target`	调度了事件的对象。target 不一定是侦听该事件的对象。使用 `currentTarget` 属性可以访问侦听该事件的对象。

另请参见

HIDE

示例
如何使用示例

下例创建一个 Button 组件，用于切换 List 组件的可见性：


import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

当前页: http://livedocs.adobe.com/flash/9.0_cn/ActionScriptLangRefV3/fl/events/ComponentEvent.html

ActionScript 3.0 语言和组件参考		全部包 \| 全部类 \| 语言元素 \| 索引 \| 附录 \| 约定 \| 帧无帧
ComponentEvent	属性 \| 方法 \| 常量

包	fl.events
类	public class ComponentEvent
继承	ComponentEvent Event Object