flash.display.Sprite (ActionScript 3.0)

	属性	定义方
		accessibilityProperties : AccessibilityProperties 此显示对象的当前辅助功能选项。	DisplayObject
		alpha : Number 指示指定对象的 Alpha 透明度值。	DisplayObject
		blendMode : String BlendMode 类中的一个值，用于指定要使用的混合模式。	DisplayObject
		buttonMode : Boolean 指定此 sprite 的按钮模式。	Sprite
		cacheAsBitmap : Boolean 如果设置为 true，则 Flash Player 将缓存显示对象的内部位图表示形式。	DisplayObject
		constructor : Object 对类对象或给定对象实例的构造函数的引用。	Object
		contextMenu : ContextMenu 指定与此对象相关联的上下文菜单。	InteractiveObject
		doubleClickEnabled : Boolean 指定此对象是否接收 doubleClick 事件。	InteractiveObject
		dropTarget : DisplayObject [read-only] 指定拖动 sprite 时经过的显示对象，或放置 sprite 的显示对象。	Sprite
		filters : Array 包含当前与显示对象关联的每个滤镜对象的索引数组。	DisplayObject
		focusRect : Object 指定此对象是否显示焦点矩形。	InteractiveObject
		graphics : Graphics [read-only] 指定属于此 sprite 的 Graphics 对象，在此 sprite 中可执行矢量绘画命令。	Sprite
		height : Number 指示显示对象的高度，以像素为单位。	DisplayObject
		hitArea : Sprite 指定一个 sprite 用作另一个 sprite 的点击区域。	Sprite
		loaderInfo : LoaderInfo [read-only] 返回一个 LoaderInfo 对象，其中包含加载此显示对象所属的文件的相关信息。	DisplayObject
		mask : DisplayObject 调用显示对象被指定的 mask 对象遮罩。	DisplayObject
		mouseChildren : Boolean 确定对象的子项是否支持鼠标。	DisplayObjectContainer
		mouseEnabled : Boolean 指定此对象是否接收鼠标消息。	InteractiveObject
		mouseX : Number [read-only] 指示鼠标位置的 x 坐标，以像素为单位。	DisplayObject
		mouseY : Number [read-only] 指示鼠标位置的 y 坐标，以像素为单位。	DisplayObject
		name : String 指示 DisplayObject 的实例名称。	DisplayObject
		numChildren : int [read-only] 返回此对象的子项数目。	DisplayObjectContainer
		opaqueBackground : Object 指定显示对象是否由于具有某种背景颜色而不透明。	DisplayObject
		parent : DisplayObjectContainer [read-only] 指示包含此显示对象的 DisplayObjectContainer 对象。	DisplayObject
		prototype : Object [static] 对类或函数对象的原型对象的引用。	Object
		root : DisplayObject [read-only] 对于加载的 SWF 文件中的显示对象，root 属性是此 SWF 文件所表示的显示列表树结构部分中的顶级显示对象。	DisplayObject
		rotation : Number 指示 DisplayObject 实例距其原始方向的旋转程度，以度为单位。	DisplayObject
		scale9Grid : Rectangle 当前有效的缩放网格。	DisplayObject
		scaleX : Number 指示从注册点开始应用的对象的水平缩放比例（百分比）。	DisplayObject
		scaleY : Number 指示从对象注册点开始应用的对象的垂直缩放比例（百分比）。	DisplayObject
		scrollRect : Rectangle 显示对象的滚动矩形范围。	DisplayObject
		soundTransform : SoundTransform 控制此 sprite 中的声音。	Sprite
		stage : Stage [read-only] 显示对象的舞台。	DisplayObject
		tabChildren : Boolean 确定对象的子项是否支持 Tab 键。	DisplayObjectContainer
		tabEnabled : Boolean 指定此对象是否遵循 Tab 键顺序。	InteractiveObject
		tabIndex : int 指定 SWF 文件中的对象按 Tab 键顺序排列。	InteractiveObject
		textSnapshot : TextSnapshot [read-only] 返回此 DisplayObjectContainer 实例的 TextSnapshot 对象。	DisplayObjectContainer
		transform : Transform 一个对象，具有与显示对象的矩阵、颜色转换和像素范围有关的属性。	DisplayObject
		useHandCursor : Boolean 布尔值，指示当鼠标滑过其 buttonMode 属性设置为 true 的 sprite 时是否显示手指形（手形光标）。	Sprite
		visible : Boolean 显示对象是否可见。	DisplayObject
		width : Number 指示显示对象的宽度，以像素为单位。	DisplayObject
		x : Number 指示 DisplayObject 实例相对于父级 DisplayObjectContainer 本地坐标的 x 坐标。	DisplayObject
		y : Number 指示 DisplayObject 实例相对于父级 DisplayObjectContainer 本地坐标的 y 坐标。	DisplayObject

	方法	定义方
		Sprite() 创建一个新的 Sprite 实例。	Sprite
		addChild(child:DisplayObject):DisplayObject 将一个 DisplayObject 子实例添加到该 DisplayObjectContainer 实例中。	DisplayObjectContainer
		addChildAt(child:DisplayObject, index:int):DisplayObject 将一个 DisplayObject 子实例添加到该 DisplayObjectContainer 实例中。	DisplayObjectContainer
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void 使用 EventDispatcher 对象注册事件侦听器对象，以使侦听器能够接收事件通知。	EventDispatcher
		areInaccessibleObjectsUnderPoint(point:Point):Boolean 指示安全限制是否会导致出现以下情况：在列表中忽略了使用指定 point 点调用 DisplayObjectContainer.getObjectsUnderPoint() 方法时返回的所有显示对象。	DisplayObjectContainer
		contains(child:DisplayObject):Boolean 确定指定显示对象是 DisplayObjectContainer 实例的子项还是该实例本身。	DisplayObjectContainer
		dispatchEvent(event:Event):Boolean 将事件调度到事件流中。	EventDispatcher
		getBounds(targetCoordinateSpace:DisplayObject):Rectangle 返回一个矩形，该矩形定义相对于 targetCoordinateSpace 对象坐标系的显示对象区域。	DisplayObject
		getChildAt(index:int):DisplayObject 返回位于指定索引处的子显示对象实例。	DisplayObjectContainer
		getChildByName(name:String):DisplayObject 返回具有指定名称的子显示对象。	DisplayObjectContainer
		getChildIndex(child:DisplayObject):int 返回 DisplayObject 的 child 实例的索引位置。	DisplayObjectContainer
		getObjectsUnderPoint(point:Point):Array 返回对象的数组，这些对象位于指定点下，并且是该 DisplayObjectContainer 实例的子项（或孙子项，依此类推）。	DisplayObjectContainer
		getRect(targetCoordinateSpace:DisplayObject):Rectangle 返回一个矩形，该矩形根据 targetCoordinateSpace 参数定义的坐标系定义显示对象的边界，但不包括形状上的任何笔触。	DisplayObject
		globalToLocal(point:Point):Point 将 point 对象从舞台（全局）坐标转换为显示对象的（本地）坐标。	DisplayObject
		hasEventListener(type:String):Boolean 检查 EventDispatcher 对象是否为特定事件类型注册了任何侦听器。	EventDispatcher
		hasOwnProperty(name:String):Boolean 指示对象是否已经定义了指定的属性。	Object
		hitTestObject(obj:DisplayObject):Boolean 计算显示对象，以确定它是否与 obj 显示对象重叠或相交。	DisplayObject
		hitTestPoint(x:Number, y:Number, shapeFlag:Boolean = false):Boolean 计算显示对象，以确定它是否与 x 和 y 参数指定的点重叠或相交。	DisplayObject
		isPrototypeOf(theClass:Object):Boolean 指示 Object 类的实例是否在指定为参数的对象的原型链中。	Object
		localToGlobal(point:Point):Point 将 point 对象从显示对象的（本地）坐标转换为舞台（全局）坐标。	DisplayObject
		propertyIsEnumerable(name:String):Boolean 指示指定的属性是否存在、是否可枚举。	Object
		removeChild(child:DisplayObject):DisplayObject 从 DisplayObjectContainer 实例的子列表中删除指定的 child DisplayObject 实例。	DisplayObjectContainer
		removeChildAt(index:int):DisplayObject 从 DisplayObjectContainer 的子列表中指定的 index 位置删除子 DisplayObject。	DisplayObjectContainer
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void 从 EventDispatcher 对象中删除侦听器。	EventDispatcher
		setChildIndex(child:DisplayObject, index:int):void 更改现有子项在显示对象容器中的位置。	DisplayObjectContainer
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 设置循环操作动态属性的可用性。	Object
		startDrag(lockCenter:Boolean = false, bounds:Rectangle = null):void 允许用户拖动指定的 Sprite。	Sprite
		stopDrag():void 结束 startDrag() 方法。	Sprite
		swapChildren(child1:DisplayObject, child2:DisplayObject):void 交换两个指定子对象的 Z 轴顺序（从前到后顺序）。	DisplayObjectContainer
		swapChildrenAt(index1:int, index2:int):void 在子级列表中两个指定的索引位置，交换子对象的 Z 轴顺序（前后顺序）。	DisplayObjectContainer
		toString():String 返回指定对象的字符串表示形式。	Object
		valueOf():Object 返回指定对象的原始值。	Object
		willTrigger(type:String):Boolean 检查是否用此 EventDispatcher 对象或其任何始祖为指定事件类型注册了事件侦听器。	EventDispatcher

摘要	定义方
activate	Flash Player 获得操作系统焦点并变为活动状态时调度。	EventDispatcher
added	将显示对象添加到显示列表中时调度。	DisplayObject
addedToStage	在将显示对象直接添加到舞台显示列表或将包含显示对象的子树添加至舞台显示列表中时调度。	DisplayObject
click	用户在同一 InteractiveObject 上按下并释放用户指针设备的主按钮时调度。	InteractiveObject
deactivate	Flash Player 失去操作系统焦点并变为非活动状态时调度。	EventDispatcher
doubleClick	如果 InteractiveObject 的 doubleClickEnabled 标志设置为 true，当用户在该对象上快速连续按下两次并释放指针设备的主按钮时调度。	InteractiveObject
enterFrame	播放头进入新帧时调度。	DisplayObject
focusIn	显示对象获得焦点后调度。	InteractiveObject
focusOut	显示对象失去焦点后调度。	InteractiveObject
keyDown	用户按下某个键时调度。	InteractiveObject
keyFocusChange	用户尝试使用键盘导航更改焦点时调度。	InteractiveObject
keyUp	用户释放某个键时调度。	InteractiveObject
mouseDown	在 Flash Player 窗口中，用户在 InteractiveObject 实例上按下指针设备按钮时调度。	InteractiveObject
mouseFocusChange	用户尝试使用指针设备更改焦点时调度。	InteractiveObject
mouseMove	用户移动 InteractiveObject 上的指针设备时调度。	InteractiveObject
mouseOut	用户将指针设备从 InteractiveObject 实例上移开时调度。	InteractiveObject
mouseOver	在 Flash Player 窗口中，用户将指针设备移动到 InteractiveObject 实例上时调度。	InteractiveObject
mouseUp	在 Flash Player 窗口中，用户在 InteractiveObject 实例上释放指针设备按钮时调度。	InteractiveObject
mouseWheel	在 Flash Player 窗口中，鼠标滚轮滚动到 InteractiveObject 实例上时调度。	InteractiveObject
removed	将要从显示列表中删除显示对象时调度。	DisplayObject
removedFromStage	在从显示列表中直接删除显示对象或删除包含显示对象的子树时调度。	DisplayObject
render	将要更新和呈现显示列表时调度。	DisplayObject
rollOut	用户将指针设备从 InteractiveObject 实例上移开时调度。	InteractiveObject
rollOver	用户将指针设备移动到 InteractiveObject 实例上时调度。	InteractiveObject
tabChildrenChange	对象的 tabChildren 标志值发生更改时调度。	InteractiveObject
tabEnabledChange	对象的 tabEnabled 标志发生更改时调度。	InteractiveObject
tabIndexChange	对象的 tabIndex 属性值发生更改时调度。	InteractiveObject

属性详细信息

buttonMode

属性

buttonMode:Boolean [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

指定此 sprite 的按钮模式。如果为 true，则此 Sprite 的行为方式就像按钮，也就是说当鼠标指针经过 Sprite 上方时它会触发手形光标的显示，并在 Sprite 具有焦点的情况下按下 Enter 或空格键时可以接收 click 事件。通过将 useHandCursor 属性设置为 false 可以禁止显示手形光标，在此情况下将显示指针。

虽然使用 SimpleButton 类创建按钮是一种比较好的方法，但是可以使用 buttonMode 属性为 Sprite 提供某种类似按钮的功能。若要在 Tab 键顺序中包括 Sprite，请将 tabEnabled 属性（继承自 InteractiveObject 类，默认情况下为 false）设置为 true。此外，请考虑是否想要 Sprite 的子项支持鼠标。大部分按钮并未启用其子对象的鼠标交互性操作，因为此操作会混淆事件流。若要对所有子对象禁用鼠标交互性操作，则必须将 mouseChildren 属性（继承自 DisplayObjectContainer 类）设置为 false。

如果将 buttonMode 属性与 MovieClip 类（该类是 Sprite 类的子类）一起使用，则按钮可能会具有一些增加的功能。如果包括具有 _up、_over 和 _down 标签的帧，则 Flash Player 将提供自动状态更改功能（类似于 ActionScript 的以前版本中为用作按钮的影片剪辑提供的功能）。没有时间轴的 Sprite 不可以使用这些自动状态更改，因此没有要加标签的帧。

实现
public function get buttonMode():Boolean
public function set buttonMode(value:Boolean):void

另请参见

SimpleButton
Sprite.useHandCursor
InteractiveObject.tabEnabled
DisplayObjectContainer.mouseChildren

示例
如何使用示例

下例创建两个 Sprite 并将其中一个的 buttonMode 属性设置为 true，将另一个的此属性设置为 false。当您编译和运行应用程序时，这两个 Sprite 都响应鼠标事件，但只有将 buttonMode 设置为 true 的那个 Sprite 才使用手形光标并包括在 Tab 键顺序中：

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace("Click!");
}

addChild(circle1);
addChild(circle2);

dropTarget

属性

dropTarget:DisplayObject [read-only]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

指定拖动 sprite 时经过的显示对象，或放置 sprite 的显示对象。

实现
public function get dropTarget():DisplayObject

另请参见

startDrag()
stopDrag()

示例
如何使用示例

下例创建一个 circle Sprite 和两个 target Sprite。当用户将光标放在 Sprite 上并按下鼠标按键时，将对 circle Sprite 调用 startDrag() 方法；当用户释放鼠标按键时，将调用 stopDrag() 方法。这样，用户就可以拖动 sprite。松开鼠标按键时，将调用 mouseRelease() 方法，此方法又会跟踪 dropTarget 对象的 name，该对象为用户将 circle Sprite 拖动到的对象：

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

graphics

属性

graphics:Graphics [read-only]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

指定属于此 sprite 的 Graphics 对象，在此 sprite 中可执行矢量绘画命令。

实现
public function get graphics():Graphics

示例
如何使用示例

下例创建一个 circle Sprite，并使用其 graphics 属性以黄色 (0xFFCC00) 填充色绘制一个圆形：

import flash.display.Sprite;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);
addChild(circle);

hitArea

属性

hitArea:Sprite [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

指定一个 sprite 用作另一个 sprite 的点击区域。如果 hitArea 属性不存在或者其值为 null 或 undefined，则 Sprite 本身将用作点击区域。 hitArea 属性的值可以是对 Sprite 对象的引用。

可以随时更改 hitArea 属性；修改后的 Sprite 会立即使用新的点击区域行为。指定为点击区域的 Sprite 不必是可见的；虽然不可见，但其图形形状仍会作为点击区域被检测。

注意：必须将指定为点击区域的 Sprite 的 mouseEnabled 属性设置为 false。否则，可能无法使用 Sprite 按钮，因为将是指定为点击区域的 Sprite（而不是 Sprite 按钮）接收鼠标事件。

实现
public function get hitArea():Sprite
public function set hitArea(value:Sprite):void

示例
如何使用示例

下例创建一个 circle Sprite 和一个 square Sprite。 square Sprite 是 circle Sprite 的 hitArea。因此，当用户单击 square Sprite 时，circle Sprite 将调度 click 事件：

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var square:Sprite = new Sprite();
square.graphics.beginFill(0xCCFF00);
square.graphics.drawRect(200, 0, 100, 100);

circle.hitArea = square;
square.mouseEnabled = false;

circle.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void{
    trace(event.target == circle); // true
    trace(event.target == square); // false
}

addChild(circle);
addChild(square);

soundTransform

属性

soundTransform:SoundTransform [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

控制此 sprite 中的声音。

实现
public function get soundTransform():SoundTransform
public function set soundTransform(value:SoundTransform):void

另请参见

flash.media.SoundTransform

示例
如何使用示例

下例创建一个名为 container 的 Sprite，并将 Loader 对象添加到其子级列表。 Loader 对象将加载 SWF 文件。当用户单击 tf 文本字段中的链接时，mute() 方法将 container Sprite soundTransform 属性的 volume 属性设置为 true：

import flash.display.Sprite;
import flash.display.Loader;
import flash.events.IOErrorEvent;
import flash.events.MouseEvent;
import flash.net.URLRequest;
import flash.text.TextField;
import flash.media.SoundTransform;

var container:Sprite = new Sprite();
addChild(container);

var ldr:Loader = new Loader;
var urlReq:URLRequest = new URLRequest("SoundPlayer.swf");
ldr.load(urlReq);

container.addChild(ldr);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);
            
var tf:TextField = new TextField();
tf.htmlText = "<a href = 'event:Mute'>Mute / Unmute</a>";
addChild(tf);

var mySoundTransform:SoundTransform = new SoundTransform();
mySoundTransform.volume = 1;

tf.addEventListener(MouseEvent.CLICK, mute);

function mute(event:MouseEvent):void {    
    if (mySoundTransform.volume == 0) {
        mySoundTransform.volume = 1;
    } else {
        mySoundTransform.volume = 0;        
    }
    container.soundTransform = mySoundTransform;
}

function urlNotFound(event:IOErrorEvent):void {
    trace("The URL was not found."); 
}

useHandCursor

属性

useHandCursor:Boolean [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

布尔值，指示当鼠标滑过其 buttonMode 属性设置为 true 的 Sprite 时是否显示手指形（手形光标）。 useHandCursor 属性的默认值是 true。如果 useHandCursor 被设置为 true，则当鼠标滑过按钮 Sprite 时会显示用于按钮的手形光标。如果 useHandCursor 为 false，则将改用箭头指针。

可以随时更改 useHandCursor 属性；修改后的 Sprite 会立即具有新的光标外观。

实现
public function get useHandCursor():Boolean
public function set useHandCursor(value:Boolean):void

另请参见

buttonMode
DisplayObjectContainer.mouseChildren

示例
如何使用示例

下例创建两个 Sprite 并将二者的 buttonMode 属性设置为 true，但将其中一个的 useHandCursor 属性设置为 true，将另一个的此属性设置为 false。当您编译和运行应用程序时，这两个 Sprite 都作为按钮进行响应（并且都包括在 Tab 键顺序中），但只有将 useHandCursor 设置为 true 的那个 Sprite 才使用手形光标：

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.useHandCursor = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = true;
circle2.useHandCursor = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace("Click!");
}

addChild(circle1);
addChild(circle2);

构造函数详细信息

Sprite

()

构造函数

public function Sprite()

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

创建一个新的 Sprite 实例。创建 Sprite 实例后，调用 DisplayObjectContainer.addChild() 或 DisplayObjectContainer.addChildAt() 方法，以便将 Sprite 添加到父级 DisplayObjectContainer。

方法详细信息

startDrag

()

方法

public function startDrag(lockCenter:Boolean = false, bounds:Rectangle = null):void

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

允许用户拖动指定的 Sprite。 Sprite 将一直保持可拖动，直到通过调用 Sprite.stopDrag() 方法来明确停止，或直到将另一个 Sprite 变为可拖动为止。在同一时间只有一个 Sprite 是可拖动的。

参数

	`lockCenter:Boolean` (default = `false`) — 指定是将可拖动的 Sprite 锁定到鼠标位置中央 (`true`)，还是锁定到用户首次单击该 Sprite 时所在的点上 (`false`)。

	`bounds:Rectangle` (default = `null`) — 相对于 Sprite 父级的坐标的值，用于指定 Sprite 约束矩形。

另请参见

dropTarget
stopDrag()

示例
如何使用示例

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

stopDrag

()

方法

public function stopDrag():void

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

结束 startDrag() 方法。通过 startDrag() 方法变为可拖动的 Sprite 将一直保持可拖动状态，直到添加 stopDrag() 方法或另一个 Sprite 变为可拖动状态为止。在同一时间只有一个 Sprite 是可拖动的。

另请参见

dropTarget
startDrag()

示例
如何使用示例

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

示例如何使用示例

下例使用 SpriteExample 类在舞台上绘制一个橙色正方形，然后在用户单击或拖动该正方形时调度事件。执行下列步骤可完成该任务：

声明 size 属性（100 x 100 像素）和背景颜色（橙色）供以后绘制正方形时使用。
然后，构造函数创建一个新的 child Sprite 对象，并用它来添加两个事件侦听器和与之相关联的方法：mouseDownHandler() 和 mouseUpHandler()。
然后，将 child Sprite 对象传递给 draw() 方法，该方法将绘制橙色正方形。
然后，将子项放置在显示列表上，方法是调用 addChild() 方法。
事件侦听器的工作方式如下：
- mouseDownHandler()：当用户单击 Sprite 对象时，此方法将添加一个 mouseMove 事件侦听器，即可以处理鼠标移动的 mouseMoveHandler() 方法。然后调用 startDrag() 方法，此方法允许拖动 Sprite 对象。
- mouseUpHandler()：当释放鼠标按键时，将删除 mouseMove 事件侦听器，并调用 stopDrag() 方法，该方法可使橙色正方形的位置保持不变。
- mouseMoveHandler：只要按住鼠标左键不放，此方法就会指示播放器不断重绘橙色正方形。

注意：每个事件侦听器方法都声明一个局部 sprite 变量，已为该变量赋予了事件的 target 属性。


package {
    import flash.display.Sprite;
    import flash.events.*;

    public class SpriteExample extends Sprite {
        private var size:uint    = 100;
        private var bgColor:uint = 0xFFCC00;

        public function SpriteExample() {
            var child:Sprite = new Sprite();
            child.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            child.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
            draw(child);
            addChild(child);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            trace("mouseDownHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.startDrag();
        }

        private function mouseUpHandler(event:MouseEvent):void {
            trace("mouseUpHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.stopDrag();
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            event.updateAfterEvent();
        }

        private function draw(sprite:Sprite):void {
            sprite.graphics.beginFill(bgColor);
            sprite.graphics.drawRect(0, 0, size, size);
            sprite.graphics.endFill();
        }
    }
}

当前页: http://livedocs.adobe.com/flash/9.0_cn/ActionScriptLangRefV3/flash/display/Sprite.html

ActionScript 3.0 语言和组件参考		全部包 \| 全部类 \| 语言元素 \| 索引 \| 附录 \| 约定 \| 帧无帧
Sprite	属性 \| 方法 \| 事件 \| 示例

包	flash.display
类	public class Sprite
继承	Sprite DisplayObjectContainer InteractiveObject DisplayObject EventDispatcher Object
子类	FLVPlayback, FLVPlaybackCaptioning, MovieClip, UIComponent