fl.managers.StyleManager (ActionScript 3.0)

	属性	定义方
		constructor : Object 对类对象或给定对象实例的构造函数的引用。	Object
		prototype : Object [static] 对类或函数对象的原型对象的引用。	Object

	方法	定义方
		StyleManager() 创建新的 StyleManager 对象。	StyleManager
		clearComponentStyle(component:Object, name:String):void [static] 从指定组件中删除样式。	StyleManager
		clearStyle(name:String):void [static] 从文档中的所有用户界面组件中删除全局样式。	StyleManager
		getComponentStyle(component:Object, name:String):Object [static] 获取在特定组件上存在的样式。	StyleManager
		getStyle(name:String):Object [static] 按名称获取全局样式。	StyleManager
		hasOwnProperty(name:String):Boolean 指示对象是否已经定义了指定的属性。	Object
		isPrototypeOf(theClass:Object):Boolean 指示 Object 类的实例是否在指定为参数的对象的原型链中。	Object
		propertyIsEnumerable(name:String):Boolean 指示指定的属性是否存在、是否可枚举。	Object
		registerInstance(instance:UIComponent):void [static] 向样式管理器注册组件实例。	StyleManager
		setComponentStyle(component:Object, name:String, style:Object):void [static] 在某个组件类型的所有实例上设置样式，例如，在 Button 组件的所有实例上，或在 ComboBox 组件的所有实例上。	StyleManager
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 设置循环操作动态属性的可用性。	Object
		setStyle(name:String, style:Object):void [static] 为文档中的所有用户界面组件设置全局样式。	StyleManager
		toString():String 返回指定对象的字符串表示形式。	Object
		valueOf():Object 返回指定对象的原始值。	Object

构造函数详细信息

StyleManager

()

构造函数

public function StyleManager()

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

创建新的 StyleManager 对象。

方法详细信息

clearComponentStyle

()

方法

public static function clearComponentStyle(component:Object, name:String):void

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

从指定组件中删除样式。

参数

	`component:Object` — 要删除样式的组件的名称。

	`name:String` — 要删除的样式的名称。

另请参见

clearStyle()
getComponentStyle()
setComponentStyle()

clearStyle

()

方法

public static function clearStyle(name:String):void

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

从文档中的所有用户界面组件中删除全局样式。

参数

name:String — 要删除的全局样式的名称。

另请参见

clearComponentStyle()
getStyle()
setStyle()

getComponentStyle

()

方法

public static function getComponentStyle(component:Object, name:String):Object

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

获取在特定组件上存在的样式。

参数

	`component:Object` — 要在其上查找所请求样式的组件实例的名称。

	`name:String` — 要检索的样式的名称。

Object — 指定组件的所请求样式。如果没有找到指定的样式，此函数返回 null。

另请参见

clearComponentStyle()
getStyle()
setComponentStyle()

getStyle

()

方法

public static function getStyle(name:String):Object

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

按名称获取全局样式。

参数

name:String — 要检索的样式的名称。

Object — 检索的全局样式的值。

另请参见

clearStyle()
getComponentStyle()
setStyle()

registerInstance

()

方法

public static function registerInstance(instance:UIComponent):void

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

向样式管理器注册组件实例。组件实例经过实例化后，可以向样式管理器注册，以便得到样式更改的通知。组件实例可以注册，以便接收基于组件的或全局性质的样式更改的通知。

参数

instance:UIComponent — 要进行注册以便获得样式管理的组件实例。

setComponentStyle

()

方法

public static function setComponentStyle(component:Object, name:String, style:Object):void

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

在某个组件类型的所有实例上设置样式，例如，在 Button 组件的所有实例上，或在 ComboBox 组件的所有实例上。

参数

	`component:Object` — 组件类型的例子为 Button 或 ComboBox。此参数还接受用于标识一个组件类型的所有实例的组件实例或类。

	`name:String` — 要设置的样式的名称。

	`style:Object` — 说明要设置的样式的样式对象。

另请参见

clearComponentStyle()
getComponentStyle()
setStyle()

setStyle

()

方法

public static function setStyle(name:String, style:Object):void

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9.0.28.0

为文档中的所有用户界面组件设置全局样式。

参数

	`name:String` — 命名要设置的样式的字符串值。

	`style:Object` — 要设置的样式对象。该属性的值取决于用户设置的样式。例如，如果样式设置为“textFormat”，则样式属性应设置为 TextFormat 对象。样式名称和样式属性值之间不匹配可能会导致组件行为不正确。

另请参见

clearStyle()
getStyle()
setComponentStyle()

示例如何使用示例

此示例演示如何动态创建 DataGrid 并侦听其事件。

若要运行该示例，请按照下列步骤操作：

将 DataGrid、Button、Label 和 TextArea 组件添加到库中。
将该代码作为 StyleManagerExample.as 另存到 FLA 文件所在的同一目录中。
将 FLA 文件中的 Document 类设置为 StyleManagerExample。

package
{
    import fl.controls.Button;
    import fl.controls.DataGrid;
    import fl.controls.Label;
    import fl.controls.TextArea;
    import fl.core.UIComponent;
    import fl.managers.FocusManager;
    import fl.managers.StyleManager;
    import flash.display.InteractiveObject;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;
    
    public class StyleManagerExample extends Sprite 
    {
        private var btn:Button;
        private var ta1:TextArea;
        private var ta2:TextArea;
        private var ta3:TextArea;
        private var ta4:TextArea;
        private var description:Label;
        private var dg:DataGrid;
        private var formatForInstance:TextFormat;
        private var formatForGlobal:TextFormat;
        
        private var testStringHTML:String = "<body><span class='heading'>Hello </span>World...</body>";
        private var testString:String = "Lorem ipsum dolor sit amet, consectetuer adipiscing elit. Fusce vitae turpis id nibh suscipit tincidunt. Quisque nulla dui, elementum eget, rutrum in, ultricies nec, erat. Donec ante turpis, lacinia eget, semper ac, consequat eget, neque. Maecenas eleifend pharetra quam. Quisque suscipit nibh a ipsum. Donec sit amet mi eu ligula volutpat imperdiet. Ut quis velit quis lectus laoreet eleifend. Aliquam pulvinar lorem. Cras ultrices felis sit amet urna. Cras viverra porttitor est. Nulla justo. Sed scelerisque."
        
        public function StyleManagerExample() {
            setupComponents();
            setupUI();
            setupStyles();
        }
        private function setupUI():void {
            var setInstanceStyleBtn:Button = new Button();
            var clearInstanceStyleBtn:Button = new Button();
            var setClassStyleBtn:Button = new Button();
            var clearClassStyleBtn:Button = new Button();
            var setGlobalStyleBtn:Button = new Button();
            var clearGlobalStyleBtn:Button = new Button();
            
            setInstanceStyleBtn.label = "Set Instance Style";
            clearInstanceStyleBtn.label = "Clear Instance Style";
            setClassStyleBtn.label = "Set Class Style";
            clearClassStyleBtn.label = "Clear Class Style";
            setGlobalStyleBtn.label = "Set Global Style";
            clearGlobalStyleBtn.label = "Clear Global Style";
            setInstanceStyleBtn.focusEnabled = false;
            clearInstanceStyleBtn.focusEnabled = false;
            setClassStyleBtn.focusEnabled = false;
            clearClassStyleBtn.focusEnabled = false;
            setGlobalStyleBtn.focusEnabled = false;
            clearGlobalStyleBtn.focusEnabled = false;
            
            setInstanceStyleBtn.move(10,310);
            clearInstanceStyleBtn.move(10,340);
            setClassStyleBtn.move(140,310);
            clearClassStyleBtn.move(140,340);
            setGlobalStyleBtn.move(270,310);
            clearGlobalStyleBtn.move(270,340);
            setInstanceStyleBtn.setSize(120,24);
            clearInstanceStyleBtn.setSize(120,24);
            setClassStyleBtn.setSize(120,24);
            clearClassStyleBtn.setSize(120,24);
            setGlobalStyleBtn.setSize(120,24);
            clearGlobalStyleBtn.setSize(120,24);
            
            setInstanceStyleBtn.addEventListener(MouseEvent.CLICK,setInstanceStyle);
            clearInstanceStyleBtn.addEventListener(MouseEvent.CLICK,clearInstanceStyle);
            setClassStyleBtn.addEventListener(MouseEvent.CLICK,setClassStyle);
            clearClassStyleBtn.addEventListener(MouseEvent.CLICK,clearClassStyle);
            setGlobalStyleBtn.addEventListener(MouseEvent.CLICK,setGlobalStyle);
            clearGlobalStyleBtn.addEventListener(MouseEvent.CLICK,clearGlobalStyle);

            description = new Label();
            description.move(10, 370);
            description.autoSize = TextFieldAutoSize.LEFT;
            description.text = "";

            addChild(setInstanceStyleBtn);
            addChild(clearInstanceStyleBtn);
            addChild(setClassStyleBtn);
            addChild(clearClassStyleBtn);
            addChild(setGlobalStyleBtn);
            addChild(clearGlobalStyleBtn);
            addChild(description);
        }
        private function setupComponents():void {
            dg = new DataGrid();
            dg.addItem( { Name:"John Alpha",     Number:"555-123-0101" } );
            dg.addItem( { Name:"Mary Bravo",     Number:"555-372-3322" } );
            dg.addItem( { Name:"Trevor Gamma", Number:"555-485-1212" } );
            dg.addItem( { Name:"Susan Delta",     Number:"555-987-3434" } );        
            dg.move(10,10);
            dg.setSize(200,290);
            dg.columns = ["Name","Number"];
            addChild(dg);
            
            ta1 = new TextArea();
            ta1.move(220,10);
            ta1.setSize(150,140);
            ta1.text = testString;
            ta1.tabEnabled = true;
            addChild(ta1);
            
            ta2 = new TextArea();
            ta2.move(380,10);
            ta2.setSize(150,140);
            ta2.text = testString;
            ta2.tabEnabled = true;
            addChild(ta2);
            
            ta3 = new TextArea();
            ta3.move(220,160);
            ta3.setSize(150,140);
            ta3.text = testString;
            ta3.tabEnabled = true;
            addChild(ta3);
            
            ta4 = new TextArea();
            ta4.move(380,160);
            ta4.setSize(150,140);
            ta4.text = testString;
            ta4.tabEnabled = true;
            addChild(ta4);
        }
        private function setupStyles():void {
            formatForGlobal = new TextFormat();
            formatForGlobal.font = "Georgia";
            formatForGlobal.size = 10;
            formatForInstance = new TextFormat();
            formatForInstance.underline = true;            
        }
        private function setInstanceStyle(e:MouseEvent):void {
            var fm:FocusManager = new FocusManager(this);
            var uiComponent:UIComponent = fm.getFocus() as UIComponent;
            if(uiComponent is TextArea) {
                uiComponent.setStyle("textFormat",formatForInstance);    
                description.text = "The TextArea object with focus is now underlined.";            
            }
        }
        private function clearInstanceStyle(e:MouseEvent):void {
            var fm:FocusManager = new FocusManager(this);
            var uiComponent:UIComponent = fm.getFocus() as UIComponent;
            if(uiComponent is TextArea) {
                uiComponent.clearStyle("textFormat");
                description.text = "The TextArea object with focus is no longer underlined.";
            }
        }
        private function setClassStyle(e:MouseEvent):void {
            var c:Class = TextArea;
            var styleName:String = "textPadding";
            var value:Number = 10;
            StyleManager.setComponentStyle(c,styleName,value);    
            description.text = "Padding for all TextArea instances is now 10.";
        }
        private function clearClassStyle(e:MouseEvent):void {
            var styleName:String = "textPadding";
            var c:Class = TextArea;
            StyleManager.clearComponentStyle(c,styleName);                    
            description.text = "TextArea padding has been reset to the default.";
        }
        private function setGlobalStyle(e:MouseEvent):void {            
            var styleName:String = "textFormat";
            var value:Object = formatForGlobal;
            StyleManager.setStyle(styleName,value);
            description.text = "All components now use font Georgia size 10.";
        }
        private function clearGlobalStyle(e:MouseEvent):void {
            var styleName:String = "textFormat";
            StyleManager.clearStyle(styleName);    
            description.text = "Font style for all components has been cleared.";
        }
    }
}

当前页: http://livedocs.adobe.com/flash/9.0_cn/ActionScriptLangRefV3/fl/managers/StyleManager.html

ActionScript 3.0 语言和组件参考		全部包 \| 全部类 \| 语言元素 \| 索引 \| 附录 \| 约定 \| 帧无帧
StyleManager	属性 \| 方法 \| 示例

包	fl.managers
类	public class StyleManager
继承	StyleManager Object