flash.geom.Transform (ActionScript 3.0)

	属性	定义方
		colorTransform : ColorTransform 一个 ColorTransform 对象，其中包含整体调整显示对象颜色的值。	Transform
		concatenatedColorTransform : ColorTransform [read-only] 一个 ColorTransform 对象，表示应用于此显示对象及其所有父级对象的组合颜色转换，回到根级别。	Transform
		concatenatedMatrix : Matrix [read-only] 一个 Matrix 对象，表示此显示对象及其所有父级对象的组合转换矩阵，回到根级别。	Transform
		constructor : Object 对类对象或给定对象实例的构造函数的引用。	Object
		matrix : Matrix 一个 Matrix 对象，其中包含影响显示对象的缩放、旋转和平移的值。	Transform
		pixelBounds : Rectangle [read-only] 一个 Rectangle 对象，定义舞台上显示对象的边界矩形。	Transform
		prototype : Object [static] 对类或函数对象的原型对象的引用。	Object

	方法	定义方
		hasOwnProperty(name:String):Boolean 指示对象是否已经定义了指定的属性。	Object
		isPrototypeOf(theClass:Object):Boolean 指示 Object 类的实例是否在指定为参数的对象的原型链中。	Object
		propertyIsEnumerable(name:String):Boolean 指示指定的属性是否存在、是否可枚举。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 设置循环操作动态属性的可用性。	Object
		toString():String 返回指定对象的字符串表示形式。	Object
		valueOf():Object 返回指定对象的原始值。	Object

属性详细信息

colorTransform

属性

colorTransform:ColorTransform [read-write]

Player 版本 :

Flash Player 9

一个 ColorTransform 对象，其中包含整体调整显示对象颜色的值。

实现
public function get colorTransform():ColorTransform
public function set colorTransform(value:ColorTransform):void

引发

TypeError — 设置时 colorTransform 为 null

另请参见

flash.geom.ColorTransform

concatenatedColorTransform

属性

concatenatedColorTransform:ColorTransform [read-only]

Player 版本 :

Flash Player 9

一个 ColorTransform 对象，表示应用于此显示对象及其所有父级对象的组合颜色转换，回到根级别。如果在不同级别上应用了不同的颜色转换，则将其中所有转换连接成此属性的一个 ColorTransform 对象。

实现
public function get concatenatedColorTransform():ColorTransform

另请参见

flash.geom.ColorTransform

concatenatedMatrix

属性

concatenatedMatrix:Matrix [read-only]

Player 版本 :

Flash Player 9

一个 Matrix 对象，表示此显示对象及其所有父级对象的组合转换矩阵，回到根级别。如果在不同级别上应用了不同的转换矩阵，则将其中所有矩阵连接成此属性的一个矩阵。

实现
public function get concatenatedMatrix():Matrix

matrix

属性

matrix:Matrix [read-write]

Player 版本 :

Flash Player 9

一个 Matrix 对象，其中包含影响显示对象的缩放、旋转和平移的值。

实现
public function get matrix():Matrix
public function set matrix(value:Matrix):void

引发

TypeError — 设置时矩阵为 null

另请参见

flash.geom.Matrix

pixelBounds

属性

pixelBounds:Rectangle [read-only]

Player 版本 :

Flash Player 9

一个 Rectangle 对象，定义舞台上显示对象的边界矩形。

实现
public function get pixelBounds():Rectangle

示例如何使用示例

下面的示例使用 TransformExample 类来倾斜以渐变图案填充的正方形 sprite 的底边。每次用户单击正方形时，应用程序都将通过倾斜正方形来转换 sprite。这是由以下步骤完成的：

TransformExample() 构造函数创建一个新的 sprite 对象 target。
TransformExample() 构造函数调用 draw() 方法，该方法在 sprite 中绘制一个渐变正方形。
TransformExample() 构造函数为 sprite 添加 click 事件侦听器，该侦听器由 clickHandler() 方法处理。
clickHandler() 方法创建一个新的 Matrix 对象 skewMatrix，该对象被设置为应用倾斜效果。将另一个矩阵 tempMatrix 分配给 sprite 的当前转换矩阵，然后使用 concat() 方法将它与 skewMatrix 合并。将该矩阵分配给正方形 sprite 的 transform.matrix 属性。每次用户单击正方形时，对 clickHandler() 的调用都将通过倾斜正方形来修改其形状。
此外，clickHandler() 方法创建一个新的 ColorTransform 对象。 redOffset 属性设置为 redOffset 的当前值并每次增加 25。同样，blueOffset 属性每次减少 25。每次单击时，sprite 的颜色都会改变。

package {
    import flash.display.Sprite;
    import flash.display.GradientType;
    import flash.geom.Matrix;
    import flash.geom.ColorTransform;
    import flash.events.MouseEvent;

    public class TransformExample extends Sprite {
        public function TransformExample() { 
            var target:Sprite = new Sprite();
            draw(target);
            addChild(target);
            target.useHandCursor = true;
            target.buttonMode = true;
            target.addEventListener(MouseEvent.CLICK, clickHandler)
        }
        public function draw(sprite:Sprite):void {
            var red:uint = 0xFF0000;
            var green:uint = 0x00FF00;
            var blue:uint = 0x0000FF;
            var size:Number = 100;
            sprite.graphics.beginGradientFill(GradientType.LINEAR, [red, blue, green], [1, 0.5, 1], [0, 200, 255]);
            sprite.graphics.drawRect(0, 0, 100, 100);
        }
        public function clickHandler(event:MouseEvent):void {
            var skewMatrix:Matrix = new Matrix();
            skewMatrix.c = 0.25;
            var tempMatrix:Matrix = this.transform.matrix;
            tempMatrix.concat(skewMatrix);
            this.transform.matrix = tempMatrix;
            
            var rOffset:Number = this.transform.colorTransform.redOffset + 25;
            var bOffset:Number = this.transform.colorTransform.blueOffset - 25;
            this.transform.colorTransform = new ColorTransform(1, 1, 1, 1, rOffset, 0, bOffset, 0);            
        }
    }
}

当前页: http://livedocs.adobe.com/flash/9.0_cn/ActionScriptLangRefV3/flash/geom/Transform.html

ActionScript 3.0 语言和组件参考		全部包 \| 全部类 \| 语言元素 \| 索引 \| 附录 \| 约定 \| 帧无帧
Transform	属性 \| 方法 \| 示例

包	flash.geom
类	public class Transform
继承	Transform Object