flash.net.URLRequest (ActionScript 3.0)

	属性	定义方
		constructor : Object 对类对象或给定对象实例的构造函数的引用。	Object
		contentType : String 任何 POST 数据的 MIME 内容类型。	URLRequest
		data : Object 一个对象，它包含将随 URL 请求一起传输的数据。	URLRequest
		method : String 控制 HTTP 窗体提交方法是 GET 还是 POST 操作。	URLRequest
		prototype : Object [static] 对类或函数对象的原型对象的引用。	Object
		requestHeaders : Array 要追加到 HTTP 请求的 HTTP 请求标头的数组。	URLRequest
		url : String 所请求的 URL。	URLRequest

	方法	定义方
		URLRequest(url:String = null) 创建 URLRequest 对象。	URLRequest
		hasOwnProperty(name:String):Boolean 指示对象是否已经定义了指定的属性。	Object
		isPrototypeOf(theClass:Object):Boolean 指示 Object 类的实例是否在指定为参数的对象的原型链中。	Object
		propertyIsEnumerable(name:String):Boolean 指示指定的属性是否存在、是否可枚举。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 设置循环操作动态属性的可用性。	Object
		toString():String 返回指定对象的字符串表示形式。	Object
		valueOf():Object 返回指定对象的原始值。	Object

属性详细信息

contentType

属性

contentType:String [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

任何 POST 数据的 MIME 内容类型。

注意：FileReference.upload() 和 FileReference.download() 方法不支持 URLRequest.contentType 参数。

实现
public function get contentType():String
public function set contentType(value:String):void

data

属性

data:Object [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

一个对象，它包含将随 URL 请求一起传输的数据。

该属性与 method 属性一起使用。如果 URLRequest.method 的值是 POST，则使用 HTTP POST 方法将该数据和 URLRequest 对象一起传输。

如果 URLRequest.method 的值是 GET，则将使用 HTTP GET 方法将定义变量的数据随 URLRequest 对象一起发送。

URLRequest API 支持二进制 POST，并支持 URL 编码变量和字符串。该数据对象可以是 ByteArray、URLVariables 或 String 类型。

该数据的使用方式取决于所用对象的类型：

如果该对象为 ByteArray 对象，则 ByteArray 对象的二进制数据用作 POST 数据。对于 GET，不支持 ByteArray 类型的数据。对于 FileReference.upload() 和 FileReference.download()，也不支持 ByteArray 类型的数据。
如果该对象是 URLVariables 对象，并且该方法是 POST，则使用 x-www-form-urlencoded 格式对变量进行编码，并且生成的字符串会用作 POST 数据。一种例外情况是对 FileReference.upload() 的调用，在该调用中变量将作为 multipart/form-data 发布中的单独字段进行发送。
如果该对象是 URLVariables 对象，并且该方法是 GET，则 URLVariables 对象将定义要随 URLRequest 对象一起发送的变量。
否则，该对象会转换为字符串，并且该字符串会用作 POST 或 GET 数据。

在方法（如 navigateToURL() 或 FileReference.upload()）使用 URLRequest 对象前，不会发送该数据。

实现
public function get data():Object
public function set data(value:Object):void

另请参见

URLRequest.method
URLRequestMethod
URLVariables
flash.utils.ByteArray

示例
如何使用示例

下例在一个新的浏览器窗口中打开位于 http://www.[yourDomain].com/application.jsp 上的远程应用程序，并将 URLVariables 对象中捕获的有关用户会话的数据传递给该应用程序。

该示例的要点遵循：

构造函数会创建名为 request 的 URLRequest 实例，同时将远程应用程序的 URL 作为参数。
创建了一个 URLVariables 对象，并对它的两个属性进行了赋值。
URLVariables 对象被赋给了 URLRequest 对象的 data 属性。
该示例调用 navigateToURL，在一个新的浏览器窗口中打开远程应用程序的 URL。

注意：若要运行该示例，必须将该示例中的远程应用程序 URL 替换为工作 URL。此外，需要用服务器代码处理 Flash Player 在 URLVariables 对象中捕获的信息。

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

method

属性

method:String [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

控制 HTTP 窗体提交方法是 GET 还是 POST 操作。有效值是 URLRequestMethod.GET 或 URLRequestMethod.POST。

默认值为 URLRequestMethod.GET.

实现
public function get method():String
public function set method(value:String):void

引发

ArgumentError — 如果 value 参数不是 URLRequestMethod.GET 或 URLRequestMethod.POST。

另请参见

URLRequestMethod class
处理外部数据

示例
如何使用示例

下例在一个新的浏览器窗口中打开位于 http://www.[yourDomain].com/application.jsp 上的远程应用程序，并将 URLVariables 对象中捕获的有关用户会话的数据传递给该应用程序。它将 URLRequest.method 属性值显式设置为 URLRequestMethod.POST。

该示例的要点遵循：

构造函数会创建名为 request 的 URLRequest 实例，同时将远程应用程序的 URL 作为参数。
创建了一个 URLVariables 对象，并对它的两个属性进行了赋值。
URLVariables 对象被赋给了 URLRequest 对象的 data 属性。
URLRequest.method 属性的值设置为 URLRequestMethod.POST。
该示例调用 navigateToURL，在一个新的浏览器窗口中打开远程应用程序的 URL。

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

requestHeaders

属性

requestHeaders:Array [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

要追加到 HTTP 请求的 HTTP 请求标头的数组。该数组由 URLRequestHeader 对象组成。数组中的每一对象必须是包含一个名称字符串和一个值字符串的 URLRequestHeader 对象，如下所示：

  var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));

Flash Player 对请求标题进行了某些限制，有关详细信息，请参阅 URLRequestHeader 类的描述。

FileReference.upload() 和 FileReference.download() 方法不支持 URLRequest.requestHeaders 参数。

实现
public function get requestHeaders():Array
public function set requestHeaders(value:Array):void

另请参见

URLRequestHeader

url

属性

url:String [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

所请求的 URL。默认情况下，URL 所在的域必须与执行调用的 SWF 文件所在的域完全相同，包括子域。例如，分别位于 www.adobe.com 和 store.adobe.com 中的 SWF 文件的域不同。若要从不同的域中加载数据，请在承载 SWF 文件的服务器上放置一个跨域策略文件。有关详细信息，请参阅 URLRequest 类描述中的安全性文档。

实现
public function get url():String
public function set url(value:String):void

构造函数详细信息

URLRequest

()

构造函数

public function URLRequest(url:String = null)

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

创建 URLRequest 对象。如果 System.useCodePage 为 true，则使用系统代码页对该请求进行编码，而不使用 Unicode。如果 System.useCodePage 为 false，则使用 Unicode 对该请求进行编码，而不使用系统代码页。

参数

url:String (default = null) — 所请求的 URL。随后可以使用 url 属性来设置 URL。

另请参见

flash.system.System.useCodePage

示例如何使用示例

下例创建一个新的 Loader 对象，并为其传递一个包含 XML 文件路径的 URLRequest 对象。如果加载操作成功，将调度 complete 事件，并且 XML 文件中的数据会跟踪至输出。附加的事件处理函数会捕获其它事件，包括错误事件。

若要运行该示例，请将名为 XMLFile.xml 的文件与 SWF 文件放在同一个目录下。


package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {

        public function URLRequestExample() {
            var loader:URLLoader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}

当前页: http://livedocs.adobe.com/flash/9.0_cn/ActionScriptLangRefV3/flash/net/URLRequest.html

ActionScript 3.0 语言和组件参考		全部包 \| 全部类 \| 语言元素 \| 索引 \| 附录 \| 约定 \| 帧无帧
URLRequest	属性 \| 方法 \| 示例

包	flash.net
类	public final class URLRequest
继承	URLRequest Object