flash.filters.DropShadowFilter (ActionScript 3.0)

	属性	定义方
		alpha : Number 阴影颜色的 Alpha 透明度值。	DropShadowFilter
		angle : Number 阴影的角度。	DropShadowFilter
		blurX : Number 水平模糊量。	DropShadowFilter
		blurY : Number 垂直模糊量。	DropShadowFilter
		color : uint 阴影的颜色。	DropShadowFilter
		constructor : Object 对类对象或给定对象实例的构造函数的引用。	Object
		distance : Number 阴影的偏移距离，以像素为单位。	DropShadowFilter
		hideObject : Boolean 表示是否隐藏对象。	DropShadowFilter
		inner : Boolean 表示阴影是否为内侧阴影。	DropShadowFilter
		knockout : Boolean 应用挖空效果 (true)，这将有效地使对象的填色变为透明，并显示文档的背景颜色。	DropShadowFilter
		prototype : Object [static] 对类或函数对象的原型对象的引用。	Object
		quality : int 应用滤镜的次数。	DropShadowFilter
		strength : Number 印记或跨页的强度。	DropShadowFilter

	方法	定义方
		DropShadowFilter(distance:Number = 4.0, angle:Number = 45, color:uint = 0, alpha:Number = 1.0, blurX:Number = 4.0, blurY:Number = 4.0, strength:Number = 1.0, quality:int = 1, inner:Boolean = false, knockout:Boolean = false, hideObject:Boolean = false) 用指定参数创建新的 DropShadowFilter 实例。	DropShadowFilter
		clone():BitmapFilter 返回此滤镜对象的副本。	DropShadowFilter
		hasOwnProperty(name:String):Boolean 指示对象是否已经定义了指定的属性。	Object
		isPrototypeOf(theClass:Object):Boolean 指示 Object 类的实例是否在指定为参数的对象的原型链中。	Object
		propertyIsEnumerable(name:String):Boolean 指示指定的属性是否存在、是否可枚举。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 设置循环操作动态属性的可用性。	Object
		toString():String 返回指定对象的字符串表示形式。	Object
		valueOf():Object 返回指定对象的原始值。	Object

属性详细信息

alpha

属性

alpha:Number [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

阴影颜色的 Alpha 透明度值。有效值为 0.0 到 1.0。例如，.25 设置透明度值为 25%。默认值为 1.0。

实现
public function get alpha():Number
public function set alpha(value:Number):void

angle

属性

angle:Number [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

阴影的角度。有效值为 0 到 360 度（浮点）。默认值为 45。

实现
public function get angle():Number
public function set angle(value:Number):void

blurX

属性

blurX:Number [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

水平模糊量。有效值为 0 到 255.0（浮点）。默认值为 4.0。

实现
public function get blurX():Number
public function set blurX(value:Number):void

blurY

属性

blurY:Number [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

垂直模糊量。有效值为 0 到 255.0（浮点）。默认值为 4.0。

实现
public function get blurY():Number
public function set blurY(value:Number):void

color

属性

color:uint [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

阴影的颜色。有效值采用十六进制格式 0xRRGGBB。默认值为 0x000000。

实现
public function get color():uint
public function set color(value:uint):void

distance

属性

distance:Number [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

阴影的偏移距离，以像素为单位。默认值为 4.0（浮点）。

实现
public function get distance():Number
public function set distance(value:Number):void

hideObject

属性

hideObject:Boolean [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

表示是否隐藏对象。如果值为 true，则表示没有绘制对象本身，只有阴影是可见的。默认值为 false（显示对象）。

实现
public function get hideObject():Boolean
public function set hideObject(value:Boolean):void

inner

属性

inner:Boolean [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

表示阴影是否为内侧阴影。值为 true 表明是内侧阴影。默认为 false，即外侧阴影（对象外缘周围的阴影）。

实现
public function get inner():Boolean
public function set inner(value:Boolean):void

knockout

属性

knockout:Boolean [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

应用挖空效果 (true)，这将有效地使对象的填色变为透明，并显示文档的背景颜色。默认值为 false（不应用挖空效果）。

实现
public function get knockout():Boolean
public function set knockout(value:Boolean):void

quality

属性

quality:int [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

应用滤镜的次数。默认值为 BitmapFilterQuality.LOW，与应用一次滤镜等效。值 BitmapFilterQuality.MEDIUM 两次应用滤镜；值 BitmapFilterQuality.HIGH 三次应用滤镜。滤镜的值越小，呈现速度越快。

对于大多数应用，quality 的值为低、中或高就足够了。您可以使用其它数值（最高为 15）来达到不同的效果，但是值越高，呈现速度越慢。除了增加 quality 的值，仅增加 blurX 和 blurY 属性的值通常也可以获得类似的效果，而且呈现速度更快。

实现
public function get quality():int
public function set quality(value:int):void

另请参见

flash.filters.BitmapFilterQuality

strength

属性

strength:Number [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

印记或跨页的强度。该值越高，压印的颜色越深，而且阴影与背景之间的对比度也越强。有效值为 0 到 255.0。默认值为 1.0。

实现
public function get strength():Number
public function set strength(value:Number):void

构造函数详细信息

DropShadowFilter

()

构造函数

public function DropShadowFilter(distance:Number = 4.0, angle:Number = 45, color:uint = 0, alpha:Number = 1.0, blurX:Number = 4.0, blurY:Number = 4.0, strength:Number = 1.0, quality:int = 1, inner:Boolean = false, knockout:Boolean = false, hideObject:Boolean = false)

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

用指定参数创建新的 DropShadowFilter 实例。

参数

	`distance:Number` (default = `4.0`) — 阴影的偏移距离，以像素为单位。

	`angle:Number` (default = `45`) — 阴影的角度，0 到 360 度（浮点）。

	`color:uint` (default = `0`) — 阴影颜色，采用十六进制格式 0xRRGGBB。默认值为 0x000000。

	`alpha:Number` (default = `1.0`) — 阴影颜色的 Alpha 透明度值。有效值为 0.0 到 1.0。例如，.25 设置透明度值为 25%。

	`blurX:Number` (default = `4.0`) — 水平模糊量。有效值为 0 到 255.0（浮点）。

	`blurY:Number` (default = `4.0`) — 垂直模糊量。有效值为 0 到 255.0（浮点）。

	`strength:Number` (default = `1.0`) — 印记或跨页的强度。该值越高，压印的颜色越深，而且阴影与背景之间的对比度也越强。有效值为 0 到 255.0。

	`quality:int` (default = `1`) — 应用滤镜的次数。使用 BitmapFilterQuality 常数： `BitmapFilterQuality.LOW` `BitmapFilterQuality.MEDIUM` `BitmapFilterQuality.HIGH` 有关这些值的详细信息，请参阅 `quality` 属性说明。

	`inner:Boolean` (default = `false`) — 表示阴影是否为内侧阴影。值 `true` 指定内侧阴影。值 `false` 指定外侧阴影（对象外缘周围的阴影）。

	`knockout:Boolean` (default = `false`) — 应用挖空效果 (`true`)，这将有效地使对象的填色变为透明，并显示文档的背景颜色。

	`hideObject:Boolean` (default = `false`) — 表示是否隐藏对象。如果值为 `true`，则表示没有绘制对象本身，只有阴影是可见的。

另请参见

flash.filters.BitmapFilterQuality

方法详细信息

clone

()

方法

public override function clone():BitmapFilter

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

返回此滤镜对象的副本。

BitmapFilter — 具有原始 DropShadowFilter 实例的所有属性的新 DropShadowFilter 实例。

示例如何使用示例

以下示例将创建一个黄色正方形，并对它应用投影。该示例的一般工作流程如下：

声明用于绘制正方形的三个属性，将对该正方形应用滤镜。
创建构造函数。构造函数调用 draw() 方法，该方法使用 Graphics 类的方法（通过 Sprite 的 graphics 属性访问）绘制一个橙色正方形。
在构造函数中，将变量 filter 声明为 BitmapFilter 对象，并将它分配给对 getBitmapFilter() 的调用的返回值。 getBitmapFilter() 方法定义已使用的投影滤镜。
创建一个新的 Array 对象 myFilters 并将 filter 添加到数组。将 myFilters 数组分配给 DropShadowFilterExample 对象的 filters 属性。这将应用 myFilters 中包含的所有滤镜，在本例中仅为 filter。


package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.DropShadowFilter;

    public class DropShadowFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function DropShadowFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var color:Number = 0x000000;
            var angle:Number = 45;
            var alpha:Number = 0.8;
            var blurX:Number = 8;
            var blurY:Number = 8;
            var distance:Number = 15;
            var strength:Number = 0.65;
            var inner:Boolean = false;
            var knockout:Boolean = false;
            var quality:Number = BitmapFilterQuality.HIGH;
            return new DropShadowFilter(distance,
                                        angle,
                                        color,
                                        alpha,
                                        blurX,
                                        blurY,
                                        strength,
                                        quality,
                                        inner,
                                        knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}

当前页: http://livedocs.adobe.com/flash/9.0_cn/ActionScriptLangRefV3/flash/filters/DropShadowFilter.html

ActionScript 3.0 语言和组件参考		全部包 \| 全部类 \| 语言元素 \| 索引 \| 附录 \| 约定 \| 帧无帧
DropShadowFilter	属性 \| 方法 \| 示例

包	flash.filters
类	public final class DropShadowFilter
继承	DropShadowFilter BitmapFilter Object