flash.events.TextEvent (ActionScript 3.0)

	属性	定义方
		bubbles : Boolean [read-only] 指示事件是否为冒泡事件。	Event
		cancelable : Boolean [read-only] 指示是否可以阻止与事件相关联的行为。	Event
		constructor : Object 对类对象或给定对象实例的构造函数的引用。	Object
		currentTarget : Object [read-only] 当前正在使用某个事件侦听器处理 Event 对象的对象。	Event
		eventPhase : uint [read-only] 事件流中的当前阶段。	Event
		prototype : Object [static] 对类或函数对象的原型对象的引用。	Object
		target : Object [read-only] 事件目标。	Event
		text : String 在 textInput 事件中，由用户输入的字符或字符序列。	TextEvent
		type : String [read-only] 事件的类型。	Event

	方法	定义方
		TextEvent(type :String, bubbles:Boolean = false, cancelable:Boolean = false, text:String = "") 创建一个 Event 对象，其中包含有关文本事件的信息。	TextEvent
		clone():Event 创建 TextEvent 对象的副本，并设置每个属性的值以匹配原始属性值。	TextEvent
		formatToString(className:String, ... arguments):String 在自定义 Event 类中实现 toString() 方法的实用程序函数。	Event
		hasOwnProperty(name:String):Boolean 指示对象是否已经定义了指定的属性。	Object
		isDefaultPrevented():Boolean 检查是否已对事件调用 preventDefault()。	Event
		isPrototypeOf(theClass:Object):Boolean 指示 Object 类的实例是否在指定为参数的对象的原型链中。	Object
		preventDefault():void 如果可以取消事件的默认行为，则取消该行为。	Event
		propertyIsEnumerable(name:String):Boolean 指示指定的属性是否存在、是否可枚举。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 设置循环操作动态属性的可用性。	Object
		stopImmediatePropagation():void 防止对事件流中当前节点中和所有后续节点中的事件侦听器进行处理。	Event
		stopPropagation():void 防止对事件流中当前节点的后续节点中的所有事件侦听器进行处理。	Event
		toString():String 返回一个字符串，其中包含 TextEvent 对象的所有属性。	TextEvent
		valueOf():Object 返回指定对象的原始值。	Object

	常量	定义方
		ACTIVATE : String = "activate" [static] 定义 activate 事件对象的 type 属性值。	Event
		ADDED : String = "added" [static] 定义 added 事件对象的 type 属性值。	Event
		ADDED_TO_STAGE : String = "addedToStage" [static] 定义 addedToStage 事件对象的 type 属性值。	Event
		CANCEL : String = "cancel" [static] 定义 cancel 事件对象的 type 属性值。	Event
		CHANGE : String = "change" [static] 定义 change 事件对象的 type 属性值。	Event
		CLOSE : String = "close" [static] 定义 close 事件对象的 type 属性值。	Event
		COMPLETE : String = "complete" [static] 定义 complete 事件对象的 type 属性值。	Event
		CONNECT : String = "connect" [static] 定义 connect 事件对象的 type 属性值。	Event
		DEACTIVATE : String = "deactivate" [static] 定义 deactivate 事件对象的 type 属性值。	Event
		ENTER_FRAME : String = "enterFrame" [static] 定义 enterFrame 事件对象的 type 属性值。	Event
		FULLSCREEN : String = "fullScreen" [static] 定义 fullScreen 事件对象的 type 属性值。	Event
		ID3 : String = "id3" [static] 定义 id3 事件对象的 type 属性值。	Event
		INIT : String = "init" [static] 定义 init 事件对象的 type 属性值。	Event
		LINK : String = "link" [static] 定义 link 事件对象的 type 属性值。	TextEvent
		MOUSE_LEAVE : String = "mouseLeave" [static] 定义 mouseLeave 事件对象的 type 属性值。	Event
		OPEN : String = "open" [static] 定义 open 事件对象的 type 属性值。	Event
		REMOVED : String = "removed" [static] 定义 removed 事件对象的 type 属性值。	Event
		REMOVED_FROM_STAGE : String = "removedFromStage" [static] 定义 removedFromStage 事件对象的 type 属性值。	Event
		RENDER : String = "render" [static] 定义 render 事件对象的 type 属性值。	Event
		RESIZE : String = "resize" [static] 定义 resize 事件对象的 type 属性值。	Event
		SCROLL : String = "scroll" [static] 定义 scroll 事件对象的 type 属性值。	Event
		SELECT : String = "select" [static] 定义 select 事件对象的 type 属性值。	Event
		SOUND_COMPLETE : String = "soundComplete" [static] 定义 soundComplete 事件对象的 type 属性值。	Event
		TAB_CHILDREN_CHANGE : String = "tabChildrenChange" [static] 定义 tabChildrenChange 事件对象的 type 属性值。	Event
		TAB_ENABLED_CHANGE : String = "tabEnabledChange" [static] 定义 tabEnabledChange 事件对象的 type 属性值。	Event
		TAB_INDEX_CHANGE : String = "tabIndexChange" [static] 定义 tabIndexChange 事件对象的 type 属性值。	Event
		TEXT_INPUT : String = "textInput" [static] 定义 textInput 事件对象的 type 属性值。	TextEvent
		UNLOAD : String = "unload" [static] 定义 unload 事件对象的 type 属性值。	Event

属性详细信息

text

属性

text:String [read-write]

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

在 textInput 事件中，由用户输入的字符或字符序列。 For a link 事件，<a> 标签的 href 属性的 event 属性的文本。

实现
public function get text():String
public function set text(value:String):void

示例
如何使用示例

以下代码说明当用户单击超文本链接时将调度 link 事件：

 import flash.text.TextField;
 import flash.events.TextEvent;   
 
 var tf:TextField = new TextField();
 tf.htmlText = "<a href='event:myEvent'>Click Me.</a>";
 tf.addEventListener("link", clickHandler);
 addChild(tf);
 
 function clickHandler(e:TextEvent):void {
  trace(e.type); // link
  trace(e.text); // myEvent
 }

构造函数详细信息

TextEvent

()

构造函数

public function TextEvent(type
:String, bubbles:Boolean = false, cancelable:Boolean = false, text:String = "")

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

创建一个 Event 对象，其中包含有关文本事件的信息。将 Event 对象作为参数传递给事件侦听器。

参数

	`type :String` — 事件的类型。事件侦听器可以通过继承的 `type` 属性访问此信息。可能的值包括：`TextEvent.LINK` 和 `TextEvent.TEXT_INPUT`。

	`bubbles:Boolean` (default = `false`) — 确定 Event 对象是否参与事件流的冒泡阶段。事件侦听器可以通过继承的 `bubbles` 属性访问此信息。

	`cancelable:Boolean` (default = `false`) — 确定是否可以取消 Event 对象。事件侦听器可以通过继承的 `cancelable` 属性访问此信息。

	`text:String` (default = "") — 用户输入的一个或多个文本字符。事件侦听器可以通过 `text` 属性访问此信息。

另请参见

flash.text.TextField

方法详细信息

clone

()

方法

public override function clone():Event

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

创建 TextEvent 对象的副本，并设置每个属性的值以匹配原始属性值。

Event — 其属性值与原始属性值匹配的新 TextEvent 对象。

toString

()

方法

public override function toString():String

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

返回一个字符串，其中包含 TextEvent 对象的所有属性。字符串的格式如下：

[TextEvent type=value bubbles=value cancelable=value text=value]

String — 一个字符串，其中包含 TextEvent 对象的所有属性。

常量详细信息

LINK

常量

public static const LINK:String = "link"

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

定义 link 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`true`
`cancelable`	`false`；没有要取消的默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	包含已单击的超链接的文本字段。 `target` 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`text`	URL 中“event:”之后的其余部分

另请参见

text
flash.text.TextField.link

TEXT_INPUT

常量

public static const TEXT_INPUT:String = "textInput"

语言版本 :

ActionScript 3.0

Player 版本 :

Flash Player 9

定义 textInput 事件对象的 type 属性值。

此事件具有以下属性：

属性	值
`bubbles`	`true`
`cancelable`	`true`；调用 `preventDefault()` 方法以取消默认行为。
`currentTarget`	当前正在使用某个事件侦听器处理 Event 对象的对象。
`target`	在其中输入字符的文本字段。 target 不一定是显示列表中注册此事件侦听器的对象。请使用 `currentTarget` 属性来访问显示列表中当前正在处理此事件的对象。
`text`	用户输入的字符或字符序列。

另请参见

flash.text.TextField.textInput
text

示例如何使用示例

以下示例使用 TextEventExample 类创建文本字段，并侦听这些字段上的各个文本事件。该示例执行下列任务：

本示例声明了以后要使用的两个 URL 的常量。
本示例声明了以后要使用的类型为 TextField 的两个变量。
类构造函数调用以下两个方法：
- init() 初始化 TextField 对象并将事件侦听器添加到这些对象中。
- draw() 将 TextField 添加到显示列表中并赋予要显示的文本。
侦听器 linkHandler() 和 textInputHandler() 根据其事件类型响应事件。如果 Web 浏览器尚未打开，则 linkHandler() 方法将打开 Web 浏览器，并导航到单击的 URL。每次在关联的文本字段中按下某个键时，textInputHandler() 方法仅显示信息。

注意：本示例中显示的域是虚构的，[yourDomain] 应该替换为一个真实存在的域。

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldType;
    import flash.text.TextFieldAutoSize;
    import flash.events.TextEvent;
    import flash.events.TextEvent;
    import flash.net.URLRequest;
    import flash.net.navigateToURL;
    
    public class TextEventExample extends Sprite {
        private const DOMAIN_1_URL:String = "http://www.[yourDomain].com";
        private const DOMAIN_2_URL:String = "http://www.[yourDomain].com";
        private var linkTxt:TextField;
        private var textInputTxt:TextField;
        
        public function TextEventExample() {
            init();
            draw();
        }
        
        private function init():void {
            linkTxt = new TextField();
            linkTxt.addEventListener(TextEvent.LINK, linkHandler);
            linkTxt.height = 60;
            linkTxt.autoSize = TextFieldAutoSize.LEFT;            
            linkTxt.multiline = true;
                
            textInputTxt = new TextField();
            textInputTxt.addEventListener(TextEvent.TEXT_INPUT, textInputHandler);
            textInputTxt.type = TextFieldType.INPUT;
            textInputTxt.background = true;
            textInputTxt.border = true;
            textInputTxt.height = 20;            
        }
        
        private function draw():void {
            addChild(linkTxt);
            linkTxt.htmlText += createLink(DOMAIN_1_URL, "Click to go to first domain");
            linkTxt.htmlText += "<br />";
            linkTxt.htmlText += createLink(DOMAIN_2_URL, "Click to go to second domain");

            addChild(textInputTxt);
            textInputTxt.y = linkTxt.height;
            textInputTxt.text = "type here";
        }
        
        private function createLink(url:String, text:String):String {
            var link:String = "";
            link += "<font color='#0000FF'>";
            link += "<u>";
            link += "<b>";
            link += "<a href='event:" + url + "'>" + text + "</a>";
            link += "</b>";
            link += "</u>";
            link += "</font>";
            return link;
        }
        
        private function linkHandler(e:TextEvent):void {
            var request:URLRequest = new URLRequest(e.text);
            navigateToURL(request);
        }
        
        private function textInputHandler(e:TextEvent):void {
            trace(">> ============================");
            trace(">> e.text: " + e.text);
            trace(">> textInputTxt.text: " + textInputTxt.text);
        }
    }
}

当前页: http://livedocs.adobe.com/flash/9.0_cn/ActionScriptLangRefV3/flash/events/TextEvent.html

ActionScript 3.0 语言和组件参考		全部包 \| 全部类 \| 语言元素 \| 索引 \| 附录 \| 约定 \| 帧无帧
TextEvent	属性 \| 方法 \| 常量 \| 示例

包	flash.events
类	public class TextEvent
继承	TextEvent Event Object
子类	DataEvent, ErrorEvent, IMEEvent